mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 23:13:19 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
80 lines
1.8 KiB
Nix
80 lines
1.8 KiB
Nix
{ lib
|
|
, stdenv
|
|
, buildGoModule
|
|
, fetchFromGitHub
|
|
, gpgme
|
|
, lvm2
|
|
, btrfs-progs
|
|
, pkg-config
|
|
, go-md2man
|
|
, installShellFiles
|
|
, makeWrapper
|
|
, fuse-overlayfs
|
|
, dockerTools
|
|
, runCommand
|
|
, testers
|
|
, skopeo
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "skopeo";
|
|
version = "1.16.1";
|
|
|
|
src = fetchFromGitHub {
|
|
rev = "v${version}";
|
|
owner = "containers";
|
|
repo = "skopeo";
|
|
hash = "sha256-RsFfShru4ujB+x0hju8Xju43JJk/+PAevIPjjDC5YbQ=";
|
|
};
|
|
|
|
outputs = [ "out" "man" ];
|
|
|
|
vendorHash = null;
|
|
|
|
doCheck = false;
|
|
|
|
nativeBuildInputs = [ pkg-config go-md2man installShellFiles makeWrapper ];
|
|
|
|
buildInputs = [ gpgme ]
|
|
++ lib.optionals stdenv.hostPlatform.isLinux [ lvm2 btrfs-progs ];
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
patchShebangs .
|
|
make bin/skopeo completions docs
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
PREFIX=${placeholder "out"} make install-binary install-completions install-docs
|
|
install ${passthru.policy}/default-policy.json -Dt $out/etc/containers
|
|
'' + lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
wrapProgram $out/bin/skopeo \
|
|
--prefix PATH : ${lib.makeBinPath [ fuse-overlayfs ]}
|
|
'' + ''
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru = {
|
|
policy = runCommand "policy" { } ''
|
|
install ${src}/default-policy.json -Dt $out
|
|
'';
|
|
tests = {
|
|
version = testers.testVersion {
|
|
package = skopeo;
|
|
};
|
|
inherit (dockerTools.examples) testNixFromDockerHub;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
changelog = "https://github.com/containers/skopeo/releases/tag/${src.rev}";
|
|
description = "Command line utility for various operations on container images and image repositories";
|
|
mainProgram = "skopeo";
|
|
homepage = "https://github.com/containers/skopeo";
|
|
maintainers = with maintainers; [ lewo developer-guy ] ++ teams.podman.members;
|
|
license = licenses.asl20;
|
|
};
|
|
}
|