mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 17:03:01 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
58 lines
1.4 KiB
Nix
58 lines
1.4 KiB
Nix
# Not part of the public API – for use within nixpkgs only
|
||
#
|
||
# Usage:
|
||
# ```nix
|
||
# let
|
||
# sources = lib.importJSON ./sources.json;
|
||
# in mkMyDerivation rec {
|
||
# version = src.version; # This obviously only works for releases
|
||
# src = pkgs.npins.mkSource sources.mySource;
|
||
# }
|
||
# ```
|
||
|
||
{ fetchgit
|
||
, fetchzip
|
||
, fetchurl
|
||
}:
|
||
let
|
||
mkSource = spec:
|
||
assert spec ? type; let
|
||
path =
|
||
if spec.type == "Git" then mkGitSource spec
|
||
else if spec.type == "GitRelease" then mkGitSource spec
|
||
else if spec.type == "PyPi" then mkPyPiSource spec
|
||
else if spec.type == "Channel" then mkChannelSource spec
|
||
else throw "Unknown source type ${spec.type}";
|
||
in
|
||
spec // { outPath = path; };
|
||
|
||
mkGitSource = { repository, revision, url ? null, hash, ... }:
|
||
assert repository ? type;
|
||
# At the moment, either it is a plain git repository (which has an url), or it is a GitHub/GitLab repository
|
||
# In the latter case, there we will always be an url to the tarball
|
||
if url != null then
|
||
(fetchzip {
|
||
inherit url;
|
||
sha256 = hash;
|
||
extension = "tar";
|
||
})
|
||
else assert repository.type == "Git"; fetchgit {
|
||
url = repository.url;
|
||
rev = revision;
|
||
};
|
||
|
||
mkPyPiSource = { url, hash, ... }:
|
||
fetchurl {
|
||
inherit url;
|
||
sha256 = hash;
|
||
};
|
||
|
||
mkChannelSource = { url, hash, ... }:
|
||
fetchzip {
|
||
inherit url;
|
||
sha256 = hash;
|
||
extension = "tar";
|
||
};
|
||
in
|
||
mkSource
|