mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-23 05:14:45 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
fetchFromGitHub,
|
|
buildGoModule,
|
|
installShellFiles,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "circleci-cli";
|
|
version = "0.1.31151";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "CircleCI-Public";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-tmoDo/DvFiP6SfnQU5iNF2By5HxIuK//hj1n5+Q+cps=";
|
|
};
|
|
|
|
vendorHash = "sha256-60edYYhbSPiJWmuQXXEt+xCnSxsHf8Q38RgyWwdP6vQ=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
doCheck = false;
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X github.com/CircleCI-Public/circleci-cli/version.Version=${version}"
|
|
"-X github.com/CircleCI-Public/circleci-cli/version.Commit=${src.rev}"
|
|
"-X github.com/CircleCI-Public/circleci-cli/version.packageManager=nix"
|
|
];
|
|
|
|
postInstall = ''
|
|
mv $out/bin/circleci-cli $out/bin/circleci
|
|
|
|
installShellCompletion --cmd circleci \
|
|
--bash <(HOME=$TMPDIR $out/bin/circleci completion bash --skip-update-check) \
|
|
--zsh <(HOME=$TMPDIR $out/bin/circleci completion zsh --skip-update-check)
|
|
'';
|
|
|
|
meta = with lib; {
|
|
# Box blurb edited from the AUR package circleci-cli
|
|
description = ''
|
|
Command to enable you to reproduce the CircleCI environment locally and
|
|
run jobs as if they were running on the hosted CirleCI application.
|
|
'';
|
|
maintainers = with maintainers; [ synthetica ];
|
|
mainProgram = "circleci";
|
|
license = licenses.mit;
|
|
homepage = "https://circleci.com/";
|
|
};
|
|
}
|