mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 00:53:57 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
104 lines
2.6 KiB
Nix
104 lines
2.6 KiB
Nix
{
|
|
lib,
|
|
nodejs,
|
|
pnpm,
|
|
fetchFromGitHub,
|
|
buildGoModule,
|
|
installShellFiles,
|
|
callPackage,
|
|
nixosTests,
|
|
}:
|
|
|
|
let
|
|
inherit (import ./sources.nix { inherit fetchFromGitHub; })
|
|
pname
|
|
version
|
|
src
|
|
vendorHash
|
|
;
|
|
web = callPackage ./web.nix { inherit nodejs pnpm fetchFromGitHub; };
|
|
in
|
|
buildGoModule rec {
|
|
inherit
|
|
pname
|
|
version
|
|
src
|
|
vendorHash
|
|
;
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
## FIXME: add swagger-ui https://github.com/authelia/authelia/blob/master/cmd/authelia-scripts/cmd/build.go#L148
|
|
postPatch = ''
|
|
cp -r api internal/server/public_html
|
|
cp -r ${web}/share/authelia-web/* internal/server/public_html
|
|
'';
|
|
|
|
subPackages = [ "cmd/authelia" ];
|
|
|
|
ldflags =
|
|
let
|
|
p = "github.com/authelia/authelia/v${lib.versions.major version}/internal/utils";
|
|
in
|
|
[
|
|
"-s"
|
|
"-w"
|
|
"-X ${p}.BuildTag=v${version}"
|
|
"-X '${p}.BuildState=tagged clean'"
|
|
"-X ${p}.BuildBranch=v${version}"
|
|
"-X ${p}.BuildExtra=nixpkgs"
|
|
];
|
|
|
|
# several tests with networking and several that want chromium
|
|
doCheck = false;
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/etc/authelia
|
|
cp config.template.yml $out/etc/authelia
|
|
|
|
installShellCompletion --cmd authelia \
|
|
--bash <($out/bin/authelia completion bash) \
|
|
--fish <($out/bin/authelia completion fish) \
|
|
--zsh <($out/bin/authelia completion zsh)
|
|
'';
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
runHook preInstallCheck
|
|
|
|
$out/bin/authelia --help
|
|
$out/bin/authelia --version | grep "v${version}"
|
|
$out/bin/authelia build-info | grep 'v${version}\|nixpkgs'
|
|
|
|
runHook postInstallCheck
|
|
'';
|
|
|
|
passthru = {
|
|
# if overriding replace the postPatch to put your web UI output in internal/server/public_html
|
|
inherit web;
|
|
updateScript = ./update.sh;
|
|
tests = { inherit (nixosTests) authelia; };
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.authelia.com/";
|
|
changelog = "https://github.com/authelia/authelia/releases/tag/v${version}";
|
|
description = "Single Sign-On Multi-Factor portal for web apps";
|
|
longDescription = ''
|
|
Authelia is an open-source authentication and authorization server
|
|
providing two-factor authentication and single sign-on (SSO) for your
|
|
applications via a web portal. It acts as a companion for reverse proxies
|
|
like nginx, Traefik, caddy or HAProxy to let them know whether requests
|
|
should either be allowed or redirected to Authelia's portal for
|
|
authentication.
|
|
'';
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [
|
|
jk
|
|
dit7ya
|
|
nicomem
|
|
];
|
|
mainProgram = "authelia";
|
|
};
|
|
}
|