mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 16:43:58 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
82 lines
2.6 KiB
Nix
82 lines
2.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.snowflake-proxy;
|
|
in
|
|
{
|
|
options = {
|
|
services.snowflake-proxy = {
|
|
enable = mkEnableOption "System to defeat internet censorship";
|
|
|
|
broker = mkOption {
|
|
description = lib.mdDoc "Broker URL (default \"https://snowflake-broker.torproject.net/\")";
|
|
type = with types; nullOr str;
|
|
default = null;
|
|
};
|
|
|
|
capacity = mkOption {
|
|
description = lib.mdDoc "Limits the amount of maximum concurrent clients allowed.";
|
|
type = with types; nullOr int;
|
|
default = null;
|
|
};
|
|
|
|
relay = mkOption {
|
|
description = lib.mdDoc "websocket relay URL (default \"wss://snowflake.bamsoftware.com/\")";
|
|
type = with types; nullOr str;
|
|
default = null;
|
|
};
|
|
|
|
stun = mkOption {
|
|
description = lib.mdDoc "STUN broker URL (default \"stun:stun.stunprotocol.org:3478\")";
|
|
type = with types; nullOr str;
|
|
default = null;
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.snowflake-proxy = {
|
|
wantedBy = [ "network-online.target" ];
|
|
serviceConfig = {
|
|
ExecStart =
|
|
"${pkgs.snowflake}/bin/proxy " + concatStringsSep " " (
|
|
optional (cfg.broker != null) "-broker ${cfg.broker}"
|
|
++ optional (cfg.capacity != null) "-capacity ${builtins.toString cfg.capacity}"
|
|
++ optional (cfg.relay != null) "-relay ${cfg.relay}"
|
|
++ optional (cfg.stun != null) "-stun ${cfg.stun}"
|
|
);
|
|
|
|
# Security Hardening
|
|
# Refer to systemd.exec(5) for option descriptions.
|
|
CapabilityBoundingSet = "";
|
|
|
|
# implies RemoveIPC=, PrivateTmp=, NoNewPrivileges=, RestrictSUIDSGID=,
|
|
# ProtectSystem=strict, ProtectHome=read-only
|
|
DynamicUser = true;
|
|
LockPersonality = true;
|
|
PrivateDevices = true;
|
|
PrivateUsers = true;
|
|
ProcSubset = "pid";
|
|
ProtectClock = true;
|
|
ProtectControlGroups = true;
|
|
ProtectHome = true;
|
|
ProtectHostname = true;
|
|
ProtectKernelLogs = true;
|
|
ProtectProc = "invisible";
|
|
ProtectKernelModules = true;
|
|
ProtectKernelTunables = true;
|
|
RestrictAddressFamilies = [ "AF_INET" "AF_INET6" "AF_UNIX" ];
|
|
RestrictNamespaces = true;
|
|
RestrictRealtime = true;
|
|
SystemCallArchitectures = "native";
|
|
SystemCallFilter = "~@clock @cpu-emulation @debug @mount @obsolete @reboot @swap @privileged @resources";
|
|
UMask = "0077";
|
|
};
|
|
};
|
|
};
|
|
|
|
meta.maintainers = with maintainers; [ yayayayaka ];
|
|
}
|