mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-04 03:53:56 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
86 lines
2.1 KiB
Nix
86 lines
2.1 KiB
Nix
# Udisks daemon.
|
|
|
|
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
settingsFormat = pkgs.formats.ini {
|
|
listToValue = concatMapStringsSep "," (generators.mkValueStringDefault {});
|
|
};
|
|
configFiles = mapAttrs (name: value: (settingsFormat.generate name value)) (mapAttrs' (name: value: nameValuePair name value ) config.services.udisks2.settings);
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.udisks2 = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = lib.mdDoc ''
|
|
Whether to enable Udisks, a DBus service that allows
|
|
applications to query and manipulate storage devices.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption rec {
|
|
type = types.attrsOf settingsFormat.type;
|
|
apply = recursiveUpdate default;
|
|
default = {
|
|
"udisks2.conf" = {
|
|
udisks2 = {
|
|
modules = [ "*" ];
|
|
modules_load_preference = "ondemand";
|
|
};
|
|
defaults = {
|
|
encryption = "luks2";
|
|
};
|
|
};
|
|
};
|
|
example = literalExpression ''
|
|
{
|
|
"WDC-WD10EZEX-60M2NA0-WD-WCC3F3SJ0698.conf" = {
|
|
ATA = {
|
|
StandbyTimeout = 50;
|
|
};
|
|
};
|
|
};
|
|
'';
|
|
description = lib.mdDoc ''
|
|
Options passed to udisksd.
|
|
See [here](http://manpages.ubuntu.com/manpages/latest/en/man5/udisks2.conf.5.html) and
|
|
drive configuration in [here](http://manpages.ubuntu.com/manpages/latest/en/man8/udisks.8.html) for supported options.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf config.services.udisks2.enable {
|
|
|
|
environment.systemPackages = [ pkgs.udisks2 ];
|
|
|
|
environment.etc = mapAttrs' (name: value: nameValuePair "udisks2/${name}" { source = value; } ) configFiles;
|
|
|
|
security.polkit.enable = true;
|
|
|
|
services.dbus.packages = [ pkgs.udisks2 ];
|
|
|
|
systemd.tmpfiles.rules = [ "d /var/lib/udisks2 0755 root root -" ];
|
|
|
|
services.udev.packages = [ pkgs.udisks2 ];
|
|
|
|
systemd.packages = [ pkgs.udisks2 ];
|
|
};
|
|
|
|
}
|