mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 17:03:01 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
70 lines
1.9 KiB
Nix
70 lines
1.9 KiB
Nix
{ lib, stdenv, stdenvNoCC, fetchMavenArtifact, fetchFromGitHub, jre, makeWrapper, symlinkJoin }:
|
|
|
|
let
|
|
version = "1.0.0";
|
|
nailgun-server = fetchMavenArtifact {
|
|
groupId = "com.facebook";
|
|
artifactId = "nailgun-server";
|
|
inherit version;
|
|
sha256 = "1mk8pv0g2xg9m0gsb96plbh6mc24xrlyrmnqac5mlbl4637l4q95";
|
|
};
|
|
|
|
commonMeta = {
|
|
license = lib.licenses.asl20;
|
|
homepage = "https://www.martiansoftware.com/nailgun/";
|
|
platforms = lib.platforms.linux;
|
|
maintainers = [ ];
|
|
};
|
|
|
|
server = stdenvNoCC.mkDerivation {
|
|
pname = "nailgun-server";
|
|
inherit version;
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
dontUnpack = true;
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
makeWrapper ${jre}/bin/java $out/bin/ng-server \
|
|
--add-flags '-classpath ${nailgun-server.jar}:$CLASSPATH com.facebook.nailgun.NGServer'
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = commonMeta // {
|
|
description = "Server for running Java programs from the command line without incurring the JVM startup overhead";
|
|
sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
|
|
};
|
|
};
|
|
|
|
client = stdenv.mkDerivation {
|
|
pname = "nailgun-client";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "facebook";
|
|
repo = "nailgun";
|
|
rev = "nailgun-all-v${version}";
|
|
sha256 = "1syyk4ss5vq1zf0ma00svn56lal53ffpikgqgzngzbwyksnfdlh6";
|
|
};
|
|
|
|
makeFlags = [ "PREFIX=$(out)" ];
|
|
|
|
meta = commonMeta // {
|
|
description = "Client for running Java programs from the command line without incurring the JVM startup overhead";
|
|
};
|
|
};
|
|
in
|
|
symlinkJoin rec {
|
|
pname = "nailgun";
|
|
inherit client server version;
|
|
|
|
name = "${pname}-${version}";
|
|
paths = [ client server ];
|
|
|
|
meta = commonMeta // {
|
|
description = "Client, protocol, and server for running Java programs from the command line without incurring the JVM startup overhead";
|
|
};
|
|
}
|