mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 23:13:19 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ lib, fetchFromGitHub, stdenv
|
|
, ffmpeg, frei0r, sox, gtk3, python3, ladspaPlugins
|
|
, gobject-introspection, makeWrapper, wrapGAppsHook3
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "flowblade";
|
|
version = "2.16.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jliljebl";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-WXB071lndw4/APTgwxNVjmYBvzMXZdLn1OaWqBXjW2Q=";
|
|
};
|
|
|
|
buildInputs = [
|
|
ffmpeg frei0r sox gtk3 ladspaPlugins
|
|
(python3.withPackages (ps: with ps; [ mlt pygobject3 dbus-python numpy pillow libusb1 ]))
|
|
];
|
|
|
|
nativeBuildInputs = [ gobject-introspection makeWrapper wrapGAppsHook3 ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out
|
|
cp -a ${src}/flowblade-trunk $out/flowblade
|
|
|
|
makeWrapper $out/flowblade/flowblade $out/bin/flowblade \
|
|
--set FREI0R_PATH ${frei0r}/lib/frei0r-1 \
|
|
--set LADSPA_PATH ${ladspaPlugins}/lib/ladspa \
|
|
--prefix PATH : "${lib.makeBinPath [ ffmpeg ]}" \
|
|
''${gappsWrapperArgs[@]}
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Multitrack Non-Linear Video Editor";
|
|
homepage = "https://jliljebl.github.io/flowblade/";
|
|
license = with licenses; [ gpl3Plus ];
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ polygon ];
|
|
mainProgram = "flowblade";
|
|
};
|
|
}
|