mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-02-12 07:04:25 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
55 lines
2.0 KiB
Nix
55 lines
2.0 KiB
Nix
{ lib, stdenv, fetchurl, enableNLS ? false, libnatspec ? null, libiconv }:
|
|
|
|
assert enableNLS -> libnatspec != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "zip";
|
|
version = "3.0";
|
|
|
|
src = fetchurl {
|
|
urls = [
|
|
"ftp://ftp.info-zip.org/pub/infozip/src/zip${lib.replaceStrings ["."] [""] version}.tgz"
|
|
"https://src.fedoraproject.org/repo/pkgs/zip/zip30.tar.gz/7b74551e63f8ee6aab6fbc86676c0d37/zip30.tar.gz"
|
|
];
|
|
sha256 = "0sb3h3067pzf3a7mlxn1hikpcjrsvycjcnj9hl9b1c3ykcgvps7h";
|
|
};
|
|
prePatch = ''
|
|
substituteInPlace unix/Makefile --replace 'CC = cc' ""
|
|
'';
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
makefile = "unix/Makefile";
|
|
buildFlags = if stdenv.hostPlatform.isCygwin then [ "cygwin" ] else [ "generic" ];
|
|
installFlags = [
|
|
"prefix=${placeholder "out"}"
|
|
"INSTALL=cp"
|
|
];
|
|
|
|
patches = [
|
|
# Trying to use `memset` without declaring it is flagged as an error with clang 16, causing
|
|
# the `configure` script to incorrectly define `ZMEM`. That causes the build to fail due to
|
|
# incompatible redeclarations of `memset`, `memcpy`, and `memcmp` in `zip.h`.
|
|
./fix-memset-detection.patch
|
|
# Implicit declaration of `closedir` and `opendir` cause dirent detection to fail with clang 16.
|
|
./fix-implicit-declarations.patch
|
|
# Buffer overflow on Unicode characters in path names
|
|
# https://bugzilla.redhat.com/show_bug.cgi?id=2165653
|
|
./buffer-overflow-on-utf8-rh-bug-2165653.patch
|
|
# Fixes forward declaration errors with timezone.c
|
|
./fix-time.h-not-included.patch
|
|
] ++ lib.optionals (enableNLS && !stdenv.hostPlatform.isCygwin) [ ./natspec-gentoo.patch.bz2 ];
|
|
|
|
buildInputs = lib.optional enableNLS libnatspec
|
|
++ lib.optional stdenv.hostPlatform.isCygwin libiconv;
|
|
|
|
meta = with lib; {
|
|
description = "Compressor/archiver for creating and modifying zipfiles";
|
|
homepage = "http://www.info-zip.org";
|
|
license = licenses.bsdOriginal;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ RossComputerGuy ];
|
|
mainProgram = "zip";
|
|
};
|
|
}
|