mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 07:53:19 +00:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
101 lines
2.8 KiB
Nix
101 lines
2.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.gamemode;
|
|
settingsFormat = pkgs.formats.ini { };
|
|
configFile = settingsFormat.generate "gamemode.ini" cfg.settings;
|
|
in
|
|
{
|
|
options = {
|
|
programs.gamemode = {
|
|
enable = mkEnableOption "GameMode to optimise system performance on demand";
|
|
|
|
enableRenice = mkEnableOption "CAP_SYS_NICE on gamemoded to support lowering process niceness" // {
|
|
default = true;
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = settingsFormat.type;
|
|
default = { };
|
|
description = ''
|
|
System-wide configuration for GameMode (/etc/gamemode.ini).
|
|
See gamemoded(8) man page for available settings.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
general = {
|
|
renice = 10;
|
|
};
|
|
|
|
# Warning: GPU optimisations have the potential to damage hardware
|
|
gpu = {
|
|
apply_gpu_optimisations = "accept-responsibility";
|
|
gpu_device = 0;
|
|
amd_performance_level = "high";
|
|
};
|
|
|
|
custom = {
|
|
start = "''${pkgs.libnotify}/bin/notify-send 'GameMode started'";
|
|
end = "''${pkgs.libnotify}/bin/notify-send 'GameMode ended'";
|
|
};
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
environment = {
|
|
systemPackages = [ pkgs.gamemode ];
|
|
etc."gamemode.ini".source = configFile;
|
|
};
|
|
|
|
security = {
|
|
polkit.enable = true;
|
|
wrappers = mkIf cfg.enableRenice {
|
|
gamemoded = {
|
|
owner = "root";
|
|
group = "root";
|
|
source = "${pkgs.gamemode}/bin/gamemoded";
|
|
capabilities = "cap_sys_nice+ep";
|
|
};
|
|
};
|
|
};
|
|
|
|
systemd = {
|
|
packages = [ pkgs.gamemode ];
|
|
user.services.gamemoded = {
|
|
# The upstream service already defines this, but doesn't get applied.
|
|
# See https://github.com/NixOS/nixpkgs/issues/81138
|
|
wantedBy = [ "default.target" ];
|
|
|
|
# Use pkexec from the security wrappers to allow users to
|
|
# run libexec/cpugovctl & libexec/gpuclockctl as root with
|
|
# the the actions defined in share/polkit-1/actions.
|
|
#
|
|
# This uses a link farm to make sure other wrapped executables
|
|
# aren't included in PATH.
|
|
environment.PATH = mkForce (pkgs.linkFarm "pkexec" [
|
|
{
|
|
name = "pkexec";
|
|
path = "${config.security.wrapperDir}/pkexec";
|
|
}
|
|
]);
|
|
|
|
serviceConfig.ExecStart = mkIf cfg.enableRenice [
|
|
"" # Tell systemd to clear the existing ExecStart list, to prevent appending to it.
|
|
"${config.security.wrapperDir}/gamemoded"
|
|
];
|
|
};
|
|
};
|
|
|
|
users.groups.gamemode = { };
|
|
};
|
|
|
|
meta = {
|
|
maintainers = with maintainers; [ kira-bruneau ];
|
|
};
|
|
}
|