mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 22:53:42 +00:00
2784331d15
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/clipgrab/versions
57 lines
1.8 KiB
Nix
57 lines
1.8 KiB
Nix
{ stdenv, fetchurl, makeDesktopItem, ffmpeg
|
|
, qmake, qttools
|
|
, qtbase, qtdeclarative, qtlocation, qtquickcontrols2, qtwebchannel, qtwebengine
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "clipgrab-${version}";
|
|
version = "3.8.4";
|
|
|
|
src = fetchurl {
|
|
sha256 = "0pyrg3rrsd538vnrv6x2frhbq9k2638nzffjsar1p76wxp8fm42s";
|
|
# The .tar.bz2 "Download" link is a binary blob, the source is the .tar.gz!
|
|
url = "https://download.clipgrab.org/${name}.tar.gz";
|
|
};
|
|
|
|
buildInputs = [ ffmpeg qtbase qtdeclarative qtlocation qtquickcontrols2 qtwebchannel qtwebengine ];
|
|
nativeBuildInputs = [ qmake qttools ];
|
|
|
|
postPatch = stdenv.lib.optionalString (ffmpeg != null) ''
|
|
substituteInPlace converter_ffmpeg.cpp \
|
|
--replace '"ffmpeg"' '"${ffmpeg.bin}/bin/ffmpeg"' \
|
|
--replace '"ffmpeg ' '"${ffmpeg.bin}/bin/ffmpeg '
|
|
'';
|
|
|
|
qmakeFlags = [ "clipgrab.pro" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
desktopItem = makeDesktopItem rec {
|
|
name = "clipgrab";
|
|
exec = name;
|
|
icon = name;
|
|
desktopName = "ClipGrab";
|
|
comment = meta.description;
|
|
genericName = "Web video downloader";
|
|
categories = "Qt;AudioVideo;Audio;Video";
|
|
};
|
|
|
|
installPhase = ''
|
|
install -Dm755 clipgrab $out/bin/clipgrab
|
|
install -Dm644 icon.png $out/share/pixmaps/clipgrab.png
|
|
cp -r ${desktopItem}/share/applications $out/share
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Video downloader for YouTube and other sites";
|
|
longDescription = ''
|
|
ClipGrab is a free downloader and converter for YouTube, Vimeo, Metacafe,
|
|
Dailymotion and many other online video sites. It converts downloaded
|
|
videos to MPEG4, MP3 or other formats in just one easy step.
|
|
'';
|
|
homepage = https://clipgrab.org/;
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|