mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-18 03:34:58 +00:00
ce162ecf4b
Since 1.4.0, PolyMC simply uses LD_LIBRARY_PATH, rather than a custom GAME_LIBRARY_PATH variable. This change was made in PolyMC/PolyMC#893, which also fixes the in-tree Nix wrapper script to match. NixOS/nixpkgs#182621 updated our PolyMC to 1.4.0, but did not port the wrapper changes along. The lack of LD_LIBRARY_PATH causes libpulse to be unavailable, causing the sound issues observed in NixOS/nixpkgs#184189. Change-Id: I4042f774c1fc804609dbaa3f4206ca0dd8ab20b3
76 lines
1.8 KiB
Nix
76 lines
1.8 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, jdk8
|
|
, jdk
|
|
, zlib
|
|
, file
|
|
, wrapQtAppsHook
|
|
, xorg
|
|
, libpulseaudio
|
|
, qtbase
|
|
, libGL
|
|
, quazip
|
|
, glfw
|
|
, openal
|
|
, msaClientID ? ""
|
|
, jdks ? [ jdk jdk8 ]
|
|
, extra-cmake-modules
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "polymc";
|
|
version = "1.4.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "PolyMC";
|
|
repo = "PolyMC";
|
|
rev = version;
|
|
sha256 = "sha256-Pu2Eb3g6gwCZjJN0N6S/N82eBMLduQQUzXo8nMmtE+Y=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
nativeBuildInputs = [ extra-cmake-modules cmake file jdk wrapQtAppsHook ];
|
|
buildInputs = [ qtbase zlib quazip ];
|
|
|
|
cmakeFlags = lib.optionals (msaClientID != "") [ "-DLauncher_MSA_CLIENT_ID=${msaClientID}" ];
|
|
|
|
dontWrapQtApps = true;
|
|
|
|
postInstall = let
|
|
libpath = with xorg; lib.makeLibraryPath [
|
|
libX11
|
|
libXext
|
|
libXcursor
|
|
libXrandr
|
|
libXxf86vm
|
|
libpulseaudio
|
|
libGL
|
|
glfw
|
|
openal
|
|
stdenv.cc.cc.lib
|
|
];
|
|
in ''
|
|
# xorg.xrandr needed for LWJGL [2.9.2, 3) https://github.com/LWJGL/lwjgl/issues/128
|
|
wrapQtApp $out/bin/polymc \
|
|
--set LD_LIBRARY_PATH /run/opengl-driver/lib:${libpath} \
|
|
--prefix POLYMC_JAVA_PATHS : ${lib.makeSearchPath "bin/java" jdks} \
|
|
--prefix PATH : ${lib.makeBinPath [ xorg.xrandr ]}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://polymc.org/";
|
|
description = "A free, open source launcher for Minecraft";
|
|
longDescription = ''
|
|
Allows you to have multiple, separate instances of Minecraft (each with
|
|
their own mods, texture packs, saves, etc) and helps you manage them and
|
|
their associated options with a simple interface.
|
|
'';
|
|
platforms = platforms.linux;
|
|
changelog = "https://github.com/PolyMC/PolyMC/releases/tag/${version}";
|
|
license = licenses.gpl3Only;
|
|
maintainers = with maintainers; [ cleverca22 starcraft66 ];
|
|
};
|
|
}
|