mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 07:53:19 +00:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
87 lines
2.3 KiB
Nix
87 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let
|
|
|
|
cfg = config.services.prosody-filer;
|
|
|
|
settingsFormat = pkgs.formats.toml { };
|
|
configFile = settingsFormat.generate "prosody-filer.toml" cfg.settings;
|
|
in {
|
|
|
|
options = {
|
|
services.prosody-filer = {
|
|
enable = mkEnableOption "Prosody Filer XMPP upload file server";
|
|
|
|
settings = mkOption {
|
|
description = ''
|
|
Configuration for Prosody Filer.
|
|
Refer to <https://github.com/ThomasLeister/prosody-filer#configure-prosody-filer> for details on supported values.
|
|
'';
|
|
|
|
type = settingsFormat.type;
|
|
|
|
example = {
|
|
secret = "mysecret";
|
|
storeDir = "/srv/http/nginx/prosody-upload";
|
|
};
|
|
|
|
defaultText = literalExpression ''
|
|
{
|
|
listenport = mkDefault "127.0.0.1:5050";
|
|
uploadSubDir = mkDefault "upload/";
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
services.prosody-filer.settings = {
|
|
listenport = mkDefault "127.0.0.1:5050";
|
|
uploadSubDir = mkDefault "upload/";
|
|
};
|
|
|
|
users.users.prosody-filer = {
|
|
group = "prosody-filer";
|
|
isSystemUser = true;
|
|
};
|
|
|
|
users.groups.prosody-filer = { };
|
|
|
|
systemd.services.prosody-filer = {
|
|
description = "Prosody file upload server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
|
|
serviceConfig = {
|
|
User = "prosody-filer";
|
|
Group = "prosody-filer";
|
|
ExecStart = "${pkgs.prosody-filer}/bin/prosody-filer -config ${configFile}";
|
|
Restart = "on-failure";
|
|
CapabilityBoundingSet = "";
|
|
NoNewPrivileges = true;
|
|
PrivateDevices = true;
|
|
PrivateTmp = true;
|
|
PrivateMounts = true;
|
|
ProtectHome = true;
|
|
ProtectClock = true;
|
|
ProtectProc = "noaccess";
|
|
ProcSubset = "pid";
|
|
ProtectKernelLogs = true;
|
|
ProtectKernelModules = true;
|
|
ProtectKernelTunables = true;
|
|
ProtectControlGroups = true;
|
|
ProtectHostname = true;
|
|
RestrictSUIDSGID = true;
|
|
RestrictRealtime = true;
|
|
RestrictNamespaces = true;
|
|
LockPersonality = true;
|
|
RemoveIPC = true;
|
|
RestrictAddressFamilies = [ "AF_INET" "AF_INET6" ];
|
|
SystemCallFilter = [ "@system-service" "~@privileged" ];
|
|
};
|
|
};
|
|
};
|
|
}
|