mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-17 19:23:50 +00:00
a9a112e57f
The nsjail build has been broken since the 3.7.5 bison bump:
/nix/store/(...)/bin/ld: kafel/libkafel.a(libkafel.o):
in function `kafel_yyerror':
arm_syscalls.c:(.text+0x6833): undefined reference to `YYUSE'
The issue is coming from kafel and has been fixed upstream. More infos
at: https://github.com/google/kafel/pull/28.
Kafel being distributed through a git submodule in the nsjail repo, we
can't directly fetchpatch the fix from Github. We had to manually
modify the said patch to add a /kafel prefix.
We'll need to remove this patch for the next nsjail version bump.
44 lines
1.3 KiB
Nix
44 lines
1.3 KiB
Nix
{ lib, stdenv, fetchFromGitHub, autoconf, bison, flex, libtool, pkg-config, which
|
|
, libnl, protobuf, protobufc, shadow
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "nsjail";
|
|
version = "3.0"; # Bumping? Remove the bison patch.
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "google";
|
|
repo = "nsjail";
|
|
rev = version;
|
|
fetchSubmodules = true;
|
|
sha256 = "1w6x8xcrs0i1y3q41gyq8z3cq9x24qablklc4jiydf855lhqn4dh";
|
|
};
|
|
|
|
nativeBuildInputs = [ autoconf bison flex libtool pkg-config which ];
|
|
buildInputs = [ libnl protobuf protobufc ];
|
|
enableParallelBuilding = true;
|
|
|
|
patches = [
|
|
# To remove after bumping 3.0
|
|
./001-fix-bison-link-error.patch
|
|
];
|
|
|
|
preBuild = ''
|
|
makeFlagsArray+=(USER_DEFINES='-DNEWUIDMAP_PATH=${shadow}/bin/newuidmap -DNEWGIDMAP_PATH=${shadow}/bin/newgidmap')
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin $out/share/man/man1
|
|
install nsjail $out/bin/
|
|
install nsjail.1 $out/share/man/man1/
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A light-weight process isolation tool, making use of Linux namespaces and seccomp-bpf syscall filters";
|
|
homepage = "http://nsjail.com/";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ arturcygan bosu c0bw3b ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|