mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-15 01:15:51 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
42 lines
1.3 KiB
Nix
42 lines
1.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
# gnupg's manual describes how to setup ccid udev rules:
|
|
# https://www.gnupg.org/howtos/card-howto/en/ch02s03.html
|
|
# gnupg folks advised me (https://dev.gnupg.org/T5409) to look at debian's rules:
|
|
# https://salsa.debian.org/debian/gnupg2/-/blob/debian/main/debian/scdaemon.udev
|
|
|
|
# the latest rev of the entire debian gnupg2 repo as of 2021-04-28
|
|
# the scdaemon.udev file was last committed on 2021-01-05 (7817a03):
|
|
scdaemonUdevRev = "01898735a015541e3ffb43c7245ac1e612f40836";
|
|
|
|
scdaemonRules = pkgs.fetchurl {
|
|
url = "https://salsa.debian.org/debian/gnupg2/-/raw/${scdaemonUdevRev}/debian/scdaemon.udev";
|
|
sha256 = "08v0vp6950bz7galvc92zdss89y9vcwbinmbfcdldy8x72w6rqr3";
|
|
};
|
|
|
|
# per debian's udev deb hook (https://man7.org/linux/man-pages/man1/dh_installudev.1.html)
|
|
destination = "60-scdaemon.rules";
|
|
|
|
scdaemonUdevRulesPkg = pkgs.runCommand "scdaemon-udev-rules" { } ''
|
|
loc="$out/lib/udev/rules.d/"
|
|
mkdir -p "''${loc}"
|
|
cp "${scdaemonRules}" "''${loc}/${destination}"
|
|
'';
|
|
|
|
cfg = config.hardware.gpgSmartcards;
|
|
in
|
|
{
|
|
options.hardware.gpgSmartcards = {
|
|
enable = lib.mkEnableOption "udev rules for gnupg smart cards";
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
services.udev.packages = [ scdaemonUdevRulesPkg ];
|
|
};
|
|
}
|