mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 00:24:18 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
49 lines
1.3 KiB
Nix
49 lines
1.3 KiB
Nix
{ lib, stdenv, fetchurl, makeWrapper, asciidoc, docbook_xml_dtd_45, docbook_xsl
|
|
, coreutils, cvs, diffutils, findutils, git, python3, rsync
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "cvs-fast-export";
|
|
version = "1.63";
|
|
|
|
src = fetchurl {
|
|
url = "http://www.catb.org/~esr/cvs-fast-export/cvs-fast-export-${version}.tar.gz";
|
|
sha256 = "sha256-YZF2QebWbvn/N9pLpccudZsFHzocJp/3M0Gx9p7fQ5Y=";
|
|
};
|
|
|
|
strictDeps = true;
|
|
nativeBuildInputs = [ makeWrapper asciidoc ];
|
|
buildInputs = [ python3 ];
|
|
|
|
postPatch = ''
|
|
patchShebangs .
|
|
'';
|
|
|
|
preBuild = ''
|
|
makeFlagsArray=(
|
|
XML_CATALOG_FILES="${docbook_xml_dtd_45}/xml/dtd/docbook/catalog.xml ${docbook_xsl}/xml/xsl/docbook/catalog.xml"
|
|
LIBS=""
|
|
prefix="$out"
|
|
)
|
|
'';
|
|
|
|
env = lib.optionalAttrs stdenv.cc.isClang {
|
|
NIX_CFLAGS_COMPILE = "-Wno-implicit-function-declaration";
|
|
};
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/cvssync --prefix PATH : ${lib.makeBinPath [ rsync ]}
|
|
wrapProgram $out/bin/cvsconvert --prefix PATH : $out/bin:${lib.makeBinPath [
|
|
coreutils cvs diffutils findutils git
|
|
]}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Export an RCS or CVS history as a fast-import stream";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ dfoxfranke ];
|
|
homepage = "http://www.catb.org/esr/cvs-fast-export/";
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|