mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-28 15:54:32 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
78 lines
2.3 KiB
Nix
78 lines
2.3 KiB
Nix
{
|
|
lib,
|
|
fetchFromGitHub,
|
|
elk7Version,
|
|
buildGoModule,
|
|
libpcap,
|
|
nixosTests,
|
|
systemd,
|
|
config,
|
|
}:
|
|
|
|
let
|
|
beat =
|
|
package: extraArgs:
|
|
buildGoModule (
|
|
lib.attrsets.recursiveUpdate (rec {
|
|
pname = package;
|
|
version = elk7Version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "elastic";
|
|
repo = "beats";
|
|
rev = "v${version}";
|
|
hash = "sha256-0qwWHRIDLlnaPOCRmiiFGg+/jdanWuQtggM2QSaMR1o=";
|
|
};
|
|
|
|
vendorHash = "sha256-rwCCpptppkpvwQWUtqTjBUumP8GSpPHBTCaj0nYVQv8=";
|
|
|
|
subPackages = [ package ];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.elastic.co/products/beats";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [
|
|
fadenb
|
|
basvandijk
|
|
dfithian
|
|
];
|
|
platforms = platforms.linux;
|
|
};
|
|
}) extraArgs
|
|
);
|
|
in
|
|
rec {
|
|
auditbeat7 = beat "auditbeat" { meta.description = "Lightweight shipper for audit data"; };
|
|
filebeat7 = beat "filebeat" {
|
|
meta.description = "Lightweight shipper for logfiles";
|
|
buildInputs = [ systemd ];
|
|
tags = [ "withjournald" ];
|
|
postFixup = ''
|
|
patchelf --set-rpath ${lib.makeLibraryPath [ (lib.getLib systemd) ]} "$out/bin/filebeat"
|
|
'';
|
|
};
|
|
heartbeat7 = beat "heartbeat" { meta.description = "Lightweight shipper for uptime monitoring"; };
|
|
metricbeat7 = beat "metricbeat" {
|
|
meta.description = "Lightweight shipper for metrics";
|
|
passthru.tests = lib.optionalAttrs config.allowUnfree (
|
|
assert metricbeat7.drvPath == nixosTests.elk.unfree.ELK-7.elkPackages.metricbeat.drvPath;
|
|
{
|
|
elk = nixosTests.elk.unfree.ELK-7;
|
|
}
|
|
);
|
|
};
|
|
packetbeat7 = beat "packetbeat" {
|
|
buildInputs = [ libpcap ];
|
|
meta.description = "Network packet analyzer that ships data to Elasticsearch";
|
|
meta.longDescription = ''
|
|
Packetbeat is an open source network packet analyzer that ships the
|
|
data to Elasticsearch.
|
|
|
|
Think of it like a distributed real-time Wireshark with a lot more
|
|
analytics features. The Packetbeat shippers sniff the traffic between
|
|
your application processes, parse on the fly protocols like HTTP, MySQL,
|
|
PostgreSQL, Redis or Thrift and correlate the messages into transactions.
|
|
'';
|
|
};
|
|
}
|