mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 08:33:54 +00:00
1f6f123814
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/chromedriver/versions. These checks were done: - built on NixOS - /nix/store/r7ai8p033gdhncxsfjjy3rb8qmcsvpqx-chromedriver-2.39/bin/chromedriver passed the binary check. - Warning: no invocation of /nix/store/r7ai8p033gdhncxsfjjy3rb8qmcsvpqx-chromedriver-2.39/bin/.chromedriver-wrapped had a zero exit code or showed the expected version - 1 of 2 passed binary check by having a zero exit code. - 0 of 2 passed binary check by having the new version present in output. - found 2.39 with grep in /nix/store/r7ai8p033gdhncxsfjjy3rb8qmcsvpqx-chromedriver-2.39 - directory tree listing: https://gist.github.com/ed47d14dfe1661b73d2d877b6e790579 - du listing: https://gist.github.com/63dc7bb82190375bce025de50ed2d6fa
57 lines
1.6 KiB
Nix
57 lines
1.6 KiB
Nix
{ stdenv, fetchurl, cairo, fontconfig, freetype, gdk_pixbuf, glib
|
|
, glibc, gtk2, libX11, makeWrapper, nspr, nss, pango, unzip, gconf
|
|
, libXi, libXrender, libXext
|
|
}:
|
|
let
|
|
allSpecs = {
|
|
"x86_64-linux" = {
|
|
system = "linux64";
|
|
sha256 = "1rkdlf9v5lciaq3yp7cp2vwmca612vngbcnz55ck76jgx6rknh3g";
|
|
};
|
|
|
|
"x86_64-darwin" = {
|
|
system = "mac64";
|
|
sha256 = "11hs4mmlvxjaanq41h0dljj4sff0lfwk31svvdmzfg91idlikpsz";
|
|
};
|
|
};
|
|
|
|
spec = allSpecs."${stdenv.system}"
|
|
or (throw "missing chromedriver binary for ${stdenv.system}");
|
|
|
|
libs = stdenv.lib.makeLibraryPath [
|
|
stdenv.cc.cc.lib
|
|
cairo fontconfig freetype
|
|
gdk_pixbuf glib gtk2 gconf
|
|
libX11 nspr nss pango libXrender
|
|
gconf libXext libXi
|
|
];
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "chromedriver-${version}";
|
|
version = "2.39";
|
|
|
|
src = fetchurl {
|
|
url = "http://chromedriver.storage.googleapis.com/${version}/chromedriver_${spec.system}.zip";
|
|
sha256 = spec.sha256;
|
|
};
|
|
|
|
nativeBuildInputs = [ unzip makeWrapper ];
|
|
|
|
unpackPhase = "unzip $src";
|
|
|
|
installPhase = ''
|
|
install -m755 -D chromedriver $out/bin/chromedriver
|
|
'' + stdenv.lib.optionalString (!stdenv.isDarwin) ''
|
|
patchelf --set-interpreter ${glibc.out}/lib/ld-linux-x86-64.so.2 $out/bin/chromedriver
|
|
wrapProgram "$out/bin/chromedriver" --prefix LD_LIBRARY_PATH : "${libs}:\$LD_LIBRARY_PATH"
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://sites.google.com/a/chromium.org/chromedriver;
|
|
description = "A WebDriver server for running Selenium tests on Chrome";
|
|
license = licenses.bsd3;
|
|
maintainers = [ maintainers.goibhniu ];
|
|
platforms = attrNames allSpecs;
|
|
};
|
|
}
|