mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-07 13:33:12 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
68 lines
1.9 KiB
Nix
68 lines
1.9 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, bash
|
|
, bison
|
|
, flex
|
|
, which
|
|
, perl
|
|
, sensord ? false
|
|
, rrdtool ? null
|
|
}:
|
|
|
|
assert sensord -> rrdtool != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "lm-sensors";
|
|
version = "3.6.0";
|
|
dashedVersion = lib.replaceStrings [ "." ] [ "-" ] version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "lm-sensors";
|
|
repo = "lm-sensors";
|
|
rev = "V${dashedVersion}";
|
|
hash = "sha256-9lfHCcODlS7sZMjQhK0yQcCBEoGyZOChx/oM0CU37sY=";
|
|
};
|
|
|
|
# Upstream build system have knob to enable and disable building of static
|
|
# library, shared library is built unconditionally.
|
|
postPatch = lib.optionalString stdenv.hostPlatform.isStatic ''
|
|
sed -i 'lib/Module.mk' -e '/LIBTARGETS :=/,+1d; /-m 755/ d'
|
|
substituteInPlace prog/sensors/Module.mk --replace 'lib/$(LIBSHBASENAME)' ""
|
|
'';
|
|
|
|
nativeBuildInputs = [ bison flex which ];
|
|
# bash is required for correctly replacing the shebangs in all tools for cross-compilation.
|
|
buildInputs = [ bash perl ]
|
|
++ lib.optional sensord rrdtool;
|
|
|
|
makeFlags = [
|
|
"PREFIX=${placeholder "out"}"
|
|
"CC=${stdenv.cc.targetPrefix}cc"
|
|
"AR=${stdenv.cc.targetPrefix}ar"
|
|
] ++ lib.optional sensord "PROG_EXTRA=sensord";
|
|
|
|
installFlags = [
|
|
"ETCDIR=${placeholder "out"}/etc"
|
|
];
|
|
|
|
# Making regexp to patch-out installing of .so symlinks from Makefile is
|
|
# complicated, it is easier to remove them post-install.
|
|
postInstall = ''
|
|
mkdir -p $out/share/doc/${pname}
|
|
cp -r configs doc/* $out/share/doc/${pname}
|
|
'' + lib.optionalString stdenv.hostPlatform.isStatic ''
|
|
rm $out/lib/*.so*
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://hwmon.wiki.kernel.org/lm_sensors";
|
|
changelog = "https://raw.githubusercontent.com/lm-sensors/lm-sensors/V${dashedVersion}/CHANGES";
|
|
description = "Tools for reading hardware sensors";
|
|
license = with licenses; [ lgpl21Plus gpl2Plus ];
|
|
maintainers = with maintainers; [ pmy ];
|
|
platforms = platforms.linux;
|
|
mainProgram = "sensors";
|
|
};
|
|
}
|