mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-22 21:04:30 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
62 lines
1.6 KiB
Nix
62 lines
1.6 KiB
Nix
{ lib, stdenv, fetchFromGitHub, makeWrapper, nix-update-script
|
|
, python3, git, gnupg, less, openssh
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "git-repo";
|
|
version = "2.48";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "android";
|
|
repo = "tools_repo";
|
|
rev = "v${version}";
|
|
hash = "sha256-BrdB6SqQlLRvXbfIXHqaKD+F/SBzqGru6ISkUrEnUeQ=";
|
|
};
|
|
|
|
# Fix 'NameError: name 'ssl' is not defined'
|
|
patches = [ ./import-ssl-module.patch ];
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
buildInputs = [ python3 ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace repo --replace \
|
|
'urllib.request.urlopen(url)' \
|
|
'urllib.request.urlopen(url, context=ssl.create_default_context())'
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/bin
|
|
cp repo $out/bin/repo
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
# Important runtime dependencies
|
|
postFixup = ''
|
|
wrapProgram $out/bin/repo --prefix PATH ":" \
|
|
"${lib.makeBinPath [ git gnupg less openssh ]}"
|
|
'';
|
|
|
|
passthru = {
|
|
updateScript = nix-update-script { };
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Android's repo management tool";
|
|
longDescription = ''
|
|
Repo is a Python script based on Git that helps manage many Git
|
|
repositories, does the uploads to revision control systems, and automates
|
|
parts of the development workflow. Repo is not meant to replace Git, only
|
|
to make it easier to work with Git.
|
|
'';
|
|
homepage = "https://android.googlesource.com/tools/repo";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ otavio ];
|
|
platforms = platforms.unix;
|
|
mainProgram = "repo";
|
|
};
|
|
}
|