mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 17:03:01 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
76 lines
1.7 KiB
Nix
76 lines
1.7 KiB
Nix
{ lib
|
|
, stdenv
|
|
, gccStdenv
|
|
, autoreconfHook
|
|
, autoconf-archive
|
|
, pkg-config
|
|
, fetchurl
|
|
, fetchFromGitHub
|
|
, openal
|
|
, enet
|
|
, SDL2
|
|
, curl
|
|
, gettext
|
|
, libiconv
|
|
}:
|
|
|
|
let
|
|
version = "2.15.6";
|
|
|
|
musicVersion = lib.versions.majorMinor version;
|
|
music = stdenv.mkDerivation {
|
|
pname = "7kaa-music";
|
|
version = musicVersion;
|
|
|
|
src = fetchurl {
|
|
url = "https://www.7kfans.com/downloads/7kaa-music-${musicVersion}.tar.bz2";
|
|
hash = "sha256-sNdntuJXGaFPXzSpN0SoAi17wkr2YnW+5U38eIaVwcM=";
|
|
};
|
|
|
|
installPhase = ''
|
|
mkdir -p $out
|
|
cp -r * $out/
|
|
'';
|
|
|
|
meta.license = lib.licenses.unfree;
|
|
};
|
|
in
|
|
gccStdenv.mkDerivation (finalAttrs: {
|
|
pname = "7kaa";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "the3dfxdude";
|
|
repo = "7kaa";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-kkM+kFQ+tGHS5NrVPeDMRWFQb7waESt8xOLfFGaGdgo=";
|
|
};
|
|
|
|
nativeBuildInputs = [ autoreconfHook autoconf-archive pkg-config ];
|
|
|
|
buildInputs = [ openal enet SDL2 curl gettext libiconv ];
|
|
|
|
preAutoreconf = ''
|
|
autoupdate
|
|
'';
|
|
|
|
hardeningDisable = lib.optionals (stdenv.hostPlatform.isAarch64 && stdenv.hostPlatform.isDarwin) [ "stackprotector" ];
|
|
|
|
postInstall = ''
|
|
mkdir $out/share/7kaa/MUSIC
|
|
cp -R ${music}/MUSIC $out/share/7kaa/
|
|
cp ${music}/COPYING-Music.txt $out/share/7kaa/MUSIC
|
|
cp ${music}/COPYING-Music.txt $out/share/doc/7kaa
|
|
'';
|
|
|
|
# Multiplayer is auto-disabled for non-x86 system
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.7kfans.com";
|
|
description = "GPL release of the Seven Kingdoms with multiplayer (available only on x86 platforms)";
|
|
license = licenses.gpl2Only;
|
|
platforms = platforms.x86_64 ++ platforms.aarch64;
|
|
maintainers = with maintainers; [ _1000101 ];
|
|
};
|
|
})
|