mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-01 02:23:54 +00:00
b159458c34
With this commit, the following new upstream versions are introduced: stable: 37.0.2062.94 -> 37.0.2062.120 beta: 38.0.2125.24 -> 38.0.2125.101 dev: 39.0.2138.3 -> 39.0.2171.7 All channels built fine on my machine and were tested against a few sites. The missing_alg_import.patch now is no longer needed for version 39, so we're not applying it there anymore. Signed-off-by: aszlig <aszlig@redmoonstudios.org>
80 lines
2.1 KiB
Nix
80 lines
2.1 KiB
Nix
{ stdenv, fetchurl, python
|
|
, channel ? "stable"
|
|
, useOpenSSL # XXX
|
|
}:
|
|
|
|
with stdenv.lib;
|
|
|
|
with (import ./update.nix {
|
|
inherit (stdenv) system;
|
|
}).getChannel channel;
|
|
|
|
stdenv.mkDerivation {
|
|
name = "chromium-source-${version}";
|
|
|
|
src = fetchurl main;
|
|
|
|
buildInputs = [ python ]; # cannot patch shebangs otherwise
|
|
|
|
phases = [ "unpackPhase" "patchPhase" "installPhase" ];
|
|
|
|
opensslPatches = optional useOpenSSL openssl.patches;
|
|
|
|
prePatch = "patchShebangs .";
|
|
|
|
patches = let
|
|
onPre39 = optional (versionOlder version "39.0.0.0");
|
|
in [ ./sandbox_userns_36.patch ] ++ onPre39 ./missing_alg_import.patch;
|
|
|
|
postPatch = ''
|
|
sed -i -r \
|
|
-e 's/-f(stack-protector)(-all)?/-fno-\1/' \
|
|
-e 's|/bin/echo|echo|' \
|
|
-e "/python_arch/s/: *'[^']*'/: '""'/" \
|
|
build/common.gypi chrome/chrome_tests.gypi
|
|
'' + optionalString (versionOlder version "38.0.0.0") ''
|
|
sed -i -e '/not RunGN/,+1d' -e '/import.*depot/d' build/gyp_chromium
|
|
sed -i -e 's|/usr/bin/gcc|gcc|' \
|
|
third_party/WebKit/Source/build/scripts/scripts.gypi \
|
|
third_party/WebKit/Source/build/scripts/preprocessor.pm
|
|
'' + optionalString useOpenSSL ''
|
|
cat $opensslPatches | patch -p1 -d third_party/openssl/openssl
|
|
'';
|
|
|
|
outputs = [ "out" "sandbox" "bundled" "main" ];
|
|
installPhase = ''
|
|
mkdir -p "$out" "$sandbox" "$bundled" "$main"
|
|
|
|
header "copying browser main sources to $main"
|
|
find . -mindepth 1 -maxdepth 1 \
|
|
\! -path ./sandbox \
|
|
\! -path ./third_party \
|
|
\! -path ./build \
|
|
\! -path ./tools \
|
|
\! -name '.*' \
|
|
-print | xargs cp -rt "$main"
|
|
stopNest
|
|
|
|
header "copying sandbox components to $sandbox"
|
|
cp -rt "$sandbox" sandbox/*
|
|
stopNest
|
|
|
|
header "copying third party sources to $bundled"
|
|
cp -rt "$bundled" third_party/*
|
|
stopNest
|
|
|
|
header "copying build requisites to $out"
|
|
cp -rt "$out" build tools
|
|
stopNest
|
|
|
|
rm -rf "$out/tools/gyp" # XXX: Don't even copy it in the first place.
|
|
'';
|
|
|
|
preferLocalBuild = true;
|
|
|
|
passthru = {
|
|
inherit version channel;
|
|
plugins = fetchurl binary;
|
|
};
|
|
}
|