mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-01 02:23:54 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
76 lines
1.8 KiB
Nix
76 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildPackages,
|
|
fetchFromGitHub,
|
|
rustPlatform,
|
|
installShellFiles,
|
|
pkg-config,
|
|
apple-sdk_11,
|
|
withPCRE2 ? true,
|
|
pcre2,
|
|
}:
|
|
|
|
let
|
|
canRunRg = stdenv.hostPlatform.emulatorAvailable buildPackages;
|
|
rg = "${stdenv.hostPlatform.emulator buildPackages} $out/bin/rg";
|
|
in
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "ripgrep";
|
|
version = "14.1.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "BurntSushi";
|
|
repo = pname;
|
|
rev = version;
|
|
hash = "sha256-gyWnahj1A+iXUQlQ1O1H1u7K5euYQOld9qWm99Vjaeg=";
|
|
};
|
|
|
|
cargoHash = "sha256-b+iA8iTYWlczBpNq9eyHrWG8LMU4WPBzaU6pQRht+yE=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ] ++ lib.optional withPCRE2 pkg-config;
|
|
buildInputs =
|
|
lib.optional withPCRE2 pcre2
|
|
++ lib.optional stdenv.hostPlatform.isDarwin apple-sdk_11;
|
|
|
|
buildFeatures = lib.optional withPCRE2 "pcre2";
|
|
|
|
preFixup = lib.optionalString canRunRg ''
|
|
${rg} --generate man > rg.1
|
|
installManPage rg.1
|
|
|
|
installShellCompletion --cmd rg \
|
|
--bash <(${rg} --generate complete-bash) \
|
|
--fish <(${rg} --generate complete-fish) \
|
|
--zsh <(${rg} --generate complete-zsh)
|
|
'';
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase =
|
|
''
|
|
file="$(mktemp)"
|
|
echo "abc\nbcd\ncde" > "$file"
|
|
${rg} -N 'bcd' "$file"
|
|
${rg} -N 'cd' "$file"
|
|
''
|
|
+ lib.optionalString withPCRE2 ''
|
|
echo '(a(aa)aa)' | ${rg} -P '\((a*|(?R))*\)'
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Utility that combines the usability of The Silver Searcher with the raw speed of grep";
|
|
homepage = "https://github.com/BurntSushi/ripgrep";
|
|
changelog = "https://github.com/BurntSushi/ripgrep/releases/tag/${version}";
|
|
license = with licenses; [
|
|
unlicense # or
|
|
mit
|
|
];
|
|
maintainers = with maintainers; [
|
|
globin
|
|
ma27
|
|
zowoq
|
|
];
|
|
mainProgram = "rg";
|
|
};
|
|
}
|