mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-15 09:23:37 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
81 lines
1.8 KiB
Nix
81 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
python3,
|
|
fetchFromGitHub,
|
|
}:
|
|
|
|
let
|
|
python = python3.override {
|
|
self = python;
|
|
packageOverrides = self: super: {
|
|
lark = super.lark.overridePythonAttrs (old: rec {
|
|
# gdtoolkit needs exactly this lark version
|
|
version = "1.1.9";
|
|
src = fetchFromGitHub {
|
|
owner = "lark-parser";
|
|
repo = "lark";
|
|
rev = version;
|
|
hash = "sha256-vDu+VPAXONY8J+A6oS7EiMeOMgzGms0nWpE+DKI1MVU=";
|
|
fetchSubmodules = true;
|
|
};
|
|
patches = [ ];
|
|
});
|
|
};
|
|
};
|
|
in
|
|
python.pkgs.buildPythonApplication rec {
|
|
pname = "gdtoolkit";
|
|
version = "4.3.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Scony";
|
|
repo = "godot-gdscript-toolkit";
|
|
rev = version;
|
|
hash = "sha256-XK6s/WnbTzjCAtV8dbRPLe5olpKUglPLQdttRRMvX70=";
|
|
};
|
|
|
|
disabled = python.pythonOlder "3.7";
|
|
|
|
propagatedBuildInputs = with python.pkgs; [
|
|
docopt
|
|
lark
|
|
pyyaml
|
|
setuptools
|
|
];
|
|
|
|
doCheck = true;
|
|
|
|
nativeCheckInputs = with python.pkgs; [
|
|
pytestCheckHook
|
|
hypothesis
|
|
];
|
|
|
|
preCheck = ''
|
|
# The tests want to run the installed executables
|
|
export PATH=$out/bin:$PATH
|
|
|
|
# gdtoolkit tries to write cache variables to $HOME/.cache
|
|
export HOME=$TMP
|
|
'';
|
|
|
|
# The tests are not working on NixOS
|
|
disabledTestPaths = [
|
|
"tests/generated/test_expression_parsing.py"
|
|
"tests/gdradon/test_executable.py"
|
|
];
|
|
|
|
pythonImportsCheck = [
|
|
"gdtoolkit"
|
|
"gdtoolkit.formatter"
|
|
"gdtoolkit.linter"
|
|
"gdtoolkit.parser"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Independent set of tools for working with Godot's GDScript - parser, linter and formatter";
|
|
homepage = "https://github.com/Scony/godot-gdscript-toolkit";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ squarepear ];
|
|
};
|
|
}
|