mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-30 10:53:11 +00:00
755b915a15
nix run nixpkgs#silver-searcher -- -G '\.nix$' -0l 'description.*"[Aa]n?' pkgs \ | xargs -0 nix run nixpkgs#gnused -- -i '' -Ee 's/(description.*")[Aa]n? (.)/\1\U\2/'
72 lines
1.6 KiB
Nix
72 lines
1.6 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitLab
|
|
, openldap
|
|
, libkrb5
|
|
, libxslt
|
|
, autoreconfHook
|
|
, pkg-config
|
|
, cyrus_sasl
|
|
, util-linux
|
|
, xmlto
|
|
, docbook_xsl
|
|
, docbook_xml_dtd_43
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "adcli";
|
|
version = "0.9.2";
|
|
|
|
src = fetchFromGitLab {
|
|
domain = "gitlab.freedesktop.org";
|
|
owner = "realmd";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "sha256-dipNKlIdc1DpXLg/YJjUxZlNoMFy+rt8Y/+AfWFA4dE=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
pkg-config
|
|
docbook_xsl
|
|
util-linux
|
|
xmlto
|
|
];
|
|
|
|
buildInputs = [
|
|
openldap
|
|
libkrb5
|
|
libxslt
|
|
cyrus_sasl
|
|
];
|
|
|
|
configureFlags = [ "--disable-debug" ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace tools/Makefile.am \
|
|
--replace 'sbin_PROGRAMS' 'bin_PROGRAMS'
|
|
|
|
substituteInPlace doc/Makefile.am \
|
|
--replace 'http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl' \
|
|
'${docbook_xsl}/xml/xsl/docbook/manpages/docbook.xsl'
|
|
|
|
function patch_docbook() {
|
|
substituteInPlace $1 \
|
|
--replace "http://www.oasis-open.org/docbook/xml/4.3/docbookx.dtd" \
|
|
"${docbook_xml_dtd_43}/xml/dtd/docbook/docbookx.dtd"
|
|
}
|
|
patch_docbook doc/adcli.xml
|
|
patch_docbook doc/adcli-devel.xml
|
|
patch_docbook doc/adcli-docs.xml
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://www.freedesktop.org/software/realmd/adcli/adcli.html";
|
|
description = "Helper library and tools for Active Directory client operations";
|
|
mainProgram = "adcli";
|
|
license = licenses.lgpl21Only;
|
|
maintainers = with maintainers; [ SohamG anthonyroussel ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|