mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 04:53:27 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
74 lines
1.9 KiB
Nix
74 lines
1.9 KiB
Nix
{ lib
|
|
, stdenv
|
|
, darwin
|
|
, buildGoModule
|
|
, fetchFromGitHub
|
|
, installShellFiles
|
|
, lima
|
|
, lima-bin
|
|
, makeWrapper
|
|
, qemu
|
|
, testers
|
|
, colima
|
|
# use lima-bin on darwin to support native macOS virtualization
|
|
# https://github.com/NixOS/nixpkgs/pull/209171
|
|
, lima-drv ? if stdenv.hostPlatform.isDarwin then lima-bin else lima
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "colima";
|
|
version = "0.7.6";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "abiosoft";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
hash = "sha256-S8KmwUN5ZU21P/i6X9uSmQ25nMHZxYKd6XtawrwP6yU=";
|
|
# We need the git revision
|
|
leaveDotGit = true;
|
|
postFetch = ''
|
|
git -C $out rev-parse --short HEAD > $out/.git-revision
|
|
rm -rf $out/.git
|
|
'';
|
|
};
|
|
|
|
nativeBuildInputs = [ installShellFiles makeWrapper ]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [ darwin.DarwinTools ];
|
|
|
|
vendorHash = "sha256-caqQA+vDtC5s9qehMIMAcl8JD3Ls2wCSfOpUFPFQ9zY=";
|
|
|
|
# disable flaky Test_extractZones
|
|
# https://hydra.nixos.org/build/212378003/log
|
|
excludedPackages = "gvproxy";
|
|
|
|
CGO_ENABLED = 1;
|
|
|
|
preConfigure = ''
|
|
ldflags="-s -w -X github.com/abiosoft/colima/config.appVersion=${version} \
|
|
-X github.com/abiosoft/colima/config.revision=$(cat .git-revision)"
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram $out/bin/colima \
|
|
--prefix PATH : ${lib.makeBinPath [ lima-drv qemu ]}
|
|
|
|
installShellCompletion --cmd colima \
|
|
--bash <($out/bin/colima completion bash) \
|
|
--fish <($out/bin/colima completion fish) \
|
|
--zsh <($out/bin/colima completion zsh)
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = colima;
|
|
command = "HOME=$(mktemp -d) colima version";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Container runtimes with minimal setup";
|
|
homepage = "https://github.com/abiosoft/colima";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ aaschmid tricktron ];
|
|
mainProgram = "colima";
|
|
};
|
|
}
|