mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-24 07:53:19 +00:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
99 lines
2.6 KiB
Nix
99 lines
2.6 KiB
Nix
{ lib, pkgs, config, ... }:
|
|
with lib;
|
|
let cfg = config.services.owncast;
|
|
in {
|
|
|
|
options.services.owncast = {
|
|
|
|
enable = mkEnableOption "owncast, a video live streaming solution";
|
|
|
|
dataDir = mkOption {
|
|
type = types.str;
|
|
default = "/var/lib/owncast";
|
|
description = ''
|
|
The directory where owncast stores its data files. If left as the default value this directory will automatically be created before the owncast server starts, otherwise the sysadmin is responsible for ensuring the directory exists with appropriate ownership and permissions.
|
|
'';
|
|
};
|
|
|
|
openFirewall = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Open the appropriate ports in the firewall for owncast.
|
|
'';
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "owncast";
|
|
description = "User account under which owncast runs.";
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "owncast";
|
|
description = "Group under which owncast runs.";
|
|
};
|
|
|
|
listen = mkOption {
|
|
type = types.str;
|
|
default = "127.0.0.1";
|
|
example = "0.0.0.0";
|
|
description = "The IP address to bind the owncast web server to.";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 8080;
|
|
description = ''
|
|
TCP port where owncast web-gui listens.
|
|
'';
|
|
};
|
|
|
|
rtmp-port = mkOption {
|
|
type = types.port;
|
|
default = 1935;
|
|
description = ''
|
|
TCP port where owncast rtmp service listens.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
systemd.services.owncast = {
|
|
description = "A self-hosted live video and web chat server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = mkMerge [
|
|
{
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
WorkingDirectory = cfg.dataDir;
|
|
ExecStart = "${pkgs.owncast}/bin/owncast -webserverport ${toString cfg.port} -rtmpport ${toString cfg.rtmp-port} -webserverip ${cfg.listen}";
|
|
Restart = "on-failure";
|
|
}
|
|
(mkIf (cfg.dataDir == "/var/lib/owncast") {
|
|
StateDirectory = "owncast";
|
|
})
|
|
];
|
|
};
|
|
|
|
users.users = mkIf (cfg.user == "owncast") {
|
|
owncast = {
|
|
isSystemUser = true;
|
|
group = cfg.group;
|
|
description = "owncast system user";
|
|
};
|
|
};
|
|
|
|
users.groups = mkIf (cfg.group == "owncast") { owncast = { }; };
|
|
|
|
networking.firewall =
|
|
mkIf cfg.openFirewall { allowedTCPPorts = [ cfg.rtmp-port ] ++ optional (cfg.listen != "127.0.0.1") cfg.port; };
|
|
|
|
};
|
|
meta = { maintainers = with lib.maintainers; [ MayNiklas ]; };
|
|
}
|