mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-09 14:33:22 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
81 lines
1.7 KiB
Nix
81 lines
1.7 KiB
Nix
{ lib
|
|
, fetchFromGitHub
|
|
, python3
|
|
}:
|
|
|
|
python3.pkgs.buildPythonApplication rec {
|
|
pname = "faraday-agent-dispatcher";
|
|
version = "3.4.2";
|
|
pyproject = true;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "infobyte";
|
|
repo = "faraday_agent_dispatcher";
|
|
rev = "refs/tags/${version}";
|
|
hash = "sha256-Qr3ZGU4y7f6yHD78ecdv7a6IBFDpT+/4Yez0n/MenN0=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace setup.py \
|
|
--replace-fail '"pytest-runner",' ""
|
|
'';
|
|
|
|
pythonRelaxDeps = [
|
|
"python-socketio"
|
|
];
|
|
|
|
build-system = with python3.pkgs; [
|
|
setuptools-scm
|
|
];
|
|
|
|
dependencies = with python3.pkgs; [
|
|
aiohttp
|
|
click
|
|
faraday-agent-parameters-types
|
|
faraday-plugins
|
|
itsdangerous
|
|
psutil
|
|
pytenable
|
|
python-gvm
|
|
python-owasp-zap-v2-4
|
|
python-socketio
|
|
pyyaml
|
|
requests
|
|
syslog-rfc5424-formatter
|
|
websockets
|
|
];
|
|
|
|
nativeCheckInputs = with python3.pkgs; [
|
|
pytest-asyncio
|
|
pytestCheckHook
|
|
];
|
|
|
|
preCheck = ''
|
|
export HOME=$(mktemp -d);
|
|
'';
|
|
|
|
disabledTests = [
|
|
"test_execute_agent"
|
|
"SSL"
|
|
];
|
|
|
|
disabledTestPaths = [
|
|
# Tests require a running Docker instance
|
|
"tests/plugins-docker/test_executors.py"
|
|
"tests/unittests/test_import_official_executors.py"
|
|
];
|
|
|
|
pythonImportsCheck = [
|
|
"faraday_agent_dispatcher"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Tool to send result from tools to the Faraday Platform";
|
|
homepage = "https://github.com/infobyte/faraday_agent_dispatcher";
|
|
changelog = "https://github.com/infobyte/faraday_agent_dispatcher/releases/tag/${version}";
|
|
license = licenses.gpl3Only;
|
|
maintainers = with maintainers; [ fab ];
|
|
mainProgram = "faraday-dispatcher";
|
|
};
|
|
}
|