mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-28 09:53:10 +00:00
64 lines
1.9 KiB
Nix
64 lines
1.9 KiB
Nix
{ stdenv, fetchFromGitHub, buildDotnetPackage, dotnetPackages, gtksharp }:
|
|
|
|
let
|
|
mono-addins = dotnetPackages.MonoAddins;
|
|
in
|
|
buildDotnetPackage rec {
|
|
name = "pinta-1.6";
|
|
|
|
baseName = "Pinta";
|
|
version = "1.6";
|
|
outputFiles = [ "bin/*" ];
|
|
buildInputs = [ gtksharp mono-addins ];
|
|
xBuildFiles = [ "Pinta.sln" ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "PintaProject";
|
|
repo = "Pinta";
|
|
rev = version;
|
|
sha256 = "0vgswy981c7ys4q7js5k85sky7bz8v32wsfq3br4j41vg92pw97d";
|
|
};
|
|
|
|
# Remove version information from nodes <Reference Include="... Version=... ">
|
|
postPatch = with stdenv.lib; let
|
|
csprojFiles = [
|
|
"Pinta/Pinta.csproj"
|
|
"Pinta.Core/Pinta.Core.csproj"
|
|
"Pinta.Effects/Pinta.Effects.csproj"
|
|
"Pinta.Gui.Widgets/Pinta.Gui.Widgets.csproj"
|
|
"Pinta.Resources/Pinta.Resources.csproj"
|
|
"Pinta.Tools/Pinta.Tools.csproj"
|
|
];
|
|
versionedNames = [
|
|
"Mono\\.Addins"
|
|
"Mono\\.Posix"
|
|
"Mono\\.Addins\\.Gui"
|
|
"Mono\\.Addins\\.Setup"
|
|
];
|
|
|
|
stripVersion = name: file: let
|
|
match = ''<Reference Include="${name}([ ,][^"]*)?"'';
|
|
replace = ''<Reference Include="${name}"'';
|
|
in "sed -i -re 's/${match}/${replace}/g' ${file}\n";
|
|
|
|
# Map all possible pairs of two lists
|
|
map2 = f: listA: listB: concatMap (a: map (f a) listB) listA;
|
|
concatMap2Strings = f: listA: listB: concatStrings (map2 f listA listB);
|
|
in
|
|
concatMap2Strings stripVersion versionedNames csprojFiles;
|
|
|
|
makeWrapperArgs = [
|
|
''--prefix MONO_GAC_PREFIX ':' "${gtksharp}"''
|
|
''--prefix LD_LIBRARY_PATH ':' "${gtksharp}/lib"''
|
|
''--prefix LD_LIBRARY_PATH ':' "${gtksharp.gtk}/lib"''
|
|
];
|
|
|
|
meta = {
|
|
homepage = http://www.pinta-project.com/;
|
|
description = "Drawing/editing program modeled after Paint.NET";
|
|
license = stdenv.lib.licenses.mit;
|
|
maintainers = with stdenv.lib.maintainers; [ viric ];
|
|
platforms = with stdenv.lib.platforms; linux;
|
|
};
|
|
}
|