mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-01 02:23:54 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
89 lines
2.3 KiB
Nix
89 lines
2.3 KiB
Nix
{ lib, ... }:
|
|
let
|
|
maintainer = lib.mkOptionType {
|
|
name = "maintainer";
|
|
check = email: lib.elem email (lib.attrValues lib.maintainers);
|
|
merge =
|
|
loc: defs:
|
|
lib.listToAttrs (lib.singleton (lib.nameValuePair (lib.last defs).file (lib.last defs).value));
|
|
};
|
|
|
|
listOfMaintainers = lib.types.listOf maintainer // {
|
|
# Returns list of
|
|
# { "module-file" = [
|
|
# "maintainer1 <first@nixos.org>"
|
|
# "maintainer2 <second@nixos.org>" ];
|
|
# }
|
|
merge =
|
|
loc: defs:
|
|
lib.zipAttrs (
|
|
lib.flatten (
|
|
lib.imap1 (
|
|
n: def:
|
|
lib.imap1 (
|
|
m: def':
|
|
maintainer.merge (loc ++ [ "[${toString n}-${toString m}]" ]) [
|
|
{
|
|
inherit (def) file;
|
|
value = def';
|
|
}
|
|
]
|
|
) def.value
|
|
) defs
|
|
)
|
|
);
|
|
};
|
|
|
|
docFile = lib.types.path // {
|
|
# Returns tuples of
|
|
# { file = "module location"; value = <path/to/doc.xml>; }
|
|
merge = loc: defs: defs;
|
|
};
|
|
in
|
|
|
|
{
|
|
options = {
|
|
meta = {
|
|
|
|
maintainers = lib.mkOption {
|
|
type = listOfMaintainers;
|
|
internal = true;
|
|
default = [ ];
|
|
example = lib.literalExpression ''[ lib.maintainers.all ]'';
|
|
description = ''
|
|
List of maintainers of each module. This option should be defined at
|
|
most once per module.
|
|
'';
|
|
};
|
|
|
|
doc = lib.mkOption {
|
|
type = docFile;
|
|
internal = true;
|
|
example = "./meta.chapter.md";
|
|
description = ''
|
|
Documentation prologue for the set of options of each module. This
|
|
option should be defined at most once per module.
|
|
'';
|
|
};
|
|
|
|
buildDocsInSandbox = lib.mkOption {
|
|
type = lib.types.bool // {
|
|
merge = loc: defs: defs;
|
|
};
|
|
internal = true;
|
|
default = true;
|
|
description = ''
|
|
Whether to include this module in the split options doc build.
|
|
Disable if the module references `config`, `pkgs` or other module
|
|
arguments that cannot be evaluated as constants.
|
|
|
|
This option should be defined at most once per module.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
meta.maintainers = lib.singleton lib.maintainers.pierron;
|
|
}
|