mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-26 00:43:20 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
106 lines
2.3 KiB
Nix
106 lines
2.3 KiB
Nix
{ lib
|
|
, fetchFromGitLab
|
|
, python3
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, gobject-introspection
|
|
, desktop-file-utils
|
|
, shared-mime-info
|
|
, wrapGAppsHook4
|
|
, glib
|
|
, gtk3
|
|
, gtk4
|
|
, gtksourceview5
|
|
, libadwaita
|
|
, libhandy
|
|
, webkitgtk_4_1
|
|
, webkitgtk_6_0
|
|
, nix-update-script
|
|
}:
|
|
|
|
python3.pkgs.buildPythonApplication rec {
|
|
pname = "cambalache";
|
|
version = "0.90.4";
|
|
|
|
format = "other";
|
|
|
|
# Did not fetch submodule since it is only for tests we don't run.
|
|
src = fetchFromGitLab {
|
|
domain = "gitlab.gnome.org";
|
|
owner = "jpu";
|
|
repo = "cambalache";
|
|
rev = version;
|
|
hash = "sha256-XS6JBJuifmN2ElCGk5hITbotZ+fqEdjopL6VqmMP2y4=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
gobject-introspection # for setup hook
|
|
desktop-file-utils # for update-desktop-database
|
|
shared-mime-info # for update-mime-database
|
|
wrapGAppsHook4
|
|
];
|
|
|
|
pythonPath = with python3.pkgs; [
|
|
pygobject3
|
|
lxml
|
|
];
|
|
|
|
buildInputs = [
|
|
glib
|
|
gtk3
|
|
gtk4
|
|
gtksourceview5
|
|
webkitgtk_4_1
|
|
webkitgtk_6_0
|
|
# For extra widgets support.
|
|
libadwaita
|
|
libhandy
|
|
];
|
|
|
|
# Prevent double wrapping.
|
|
dontWrapGApps = true;
|
|
|
|
postPatch = ''
|
|
patchShebangs postinstall.py
|
|
# those programs are used at runtime not build time
|
|
# https://gitlab.gnome.org/jpu/cambalache/-/blob/0.12.1/meson.build#L79-80
|
|
substituteInPlace ./meson.build \
|
|
--replace-fail "find_program('broadwayd', required: true)" "" \
|
|
--replace-fail "find_program('gtk4-broadwayd', required: true)" ""
|
|
'';
|
|
|
|
preFixup = ''
|
|
# Let python wrapper use GNOME flags.
|
|
makeWrapperArgs+=(
|
|
# For broadway daemons
|
|
--prefix PATH : "${lib.makeBinPath [ gtk3 gtk4 ]}"
|
|
"''${gappsWrapperArgs[@]}"
|
|
)
|
|
'';
|
|
|
|
postFixup = ''
|
|
# Wrap a helper script in an unusual location.
|
|
wrapPythonProgramsIn "$out/${python3.sitePackages}/cambalache/priv/merengue" "$out $pythonPath"
|
|
'';
|
|
|
|
passthru = {
|
|
updateScript = nix-update-script { };
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = "https://gitlab.gnome.org/jpu/cambalache";
|
|
description = "RAD tool for GTK 4 and 3 with data model first philosophy";
|
|
mainProgram = "cambalache";
|
|
maintainers = teams.gnome.members;
|
|
license = with licenses; [
|
|
lgpl21Only # Cambalache
|
|
gpl2Only # tools
|
|
];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|