mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-29 10:23:29 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
47 lines
1.4 KiB
Nix
47 lines
1.4 KiB
Nix
{ lib, gccStdenv, fetchFromGitHub, bison, flex, pcre2, libunistring, ncurses }:
|
|
|
|
gccStdenv.mkDerivation rec {
|
|
pname = "boxes";
|
|
version = "2.3.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ascii-boxes";
|
|
repo = "boxes";
|
|
rev = "v${version}";
|
|
hash = "sha256-dvhb5KWBQt7g4n0ZTQMcJQljIfavV3g8i+P3PWB6Gwk=";
|
|
};
|
|
|
|
# Building instructions:
|
|
# https://boxes.thomasjensen.com/build.html#building-on-linux--unix
|
|
nativeBuildInputs = [ bison flex ];
|
|
|
|
buildInputs = [ pcre2 libunistring ncurses ];
|
|
|
|
dontConfigure = true;
|
|
|
|
# Makefile references a system wide config file in '/usr/share'. Instead, we
|
|
# move it within the store by default.
|
|
preBuild = ''
|
|
substituteInPlace Makefile \
|
|
--replace-fail "GLOBALCONF = /usr/share/boxes" \
|
|
"GLOBALCONF=${placeholder "out"}/share/boxes/boxes-config"
|
|
'';
|
|
|
|
makeFlags = [ "CC=${gccStdenv.cc.targetPrefix}cc" ];
|
|
|
|
installPhase = ''
|
|
install -Dm755 -t $out/bin out/boxes
|
|
install -Dm644 -t $out/share/boxes boxes-config
|
|
install -Dm644 -t $out/share/man/man1 doc/boxes.1
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Command line program which draws, removes, and repairs ASCII art boxes";
|
|
mainProgram = "boxes";
|
|
homepage = "https://boxes.thomasjensen.com";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ waiting-for-dev ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|