mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-24 14:43:37 +00:00
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
76 lines
2.2 KiB
Nix
76 lines
2.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.rsnapshot;
|
|
cfgfile = pkgs.writeText "rsnapshot.conf" ''
|
|
config_version 1.2
|
|
cmd_cp ${pkgs.coreutils}/bin/cp
|
|
cmd_rm ${pkgs.coreutils}/bin/rm
|
|
cmd_rsync ${pkgs.rsync}/bin/rsync
|
|
cmd_ssh ${pkgs.openssh}/bin/ssh
|
|
cmd_logger ${pkgs.inetutils}/bin/logger
|
|
cmd_du ${pkgs.coreutils}/bin/du
|
|
cmd_rsnapshot_diff ${pkgs.rsnapshot}/bin/rsnapshot-diff
|
|
lockfile /run/rsnapshot.pid
|
|
link_dest 1
|
|
|
|
${cfg.extraConfig}
|
|
'';
|
|
in
|
|
{
|
|
options = {
|
|
services.rsnapshot = {
|
|
enable = mkEnableOption "rsnapshot backups";
|
|
enableManualRsnapshot = mkOption {
|
|
description = lib.mdDoc "Whether to enable manual usage of the rsnapshot command with this module.";
|
|
default = true;
|
|
type = types.bool;
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
default = "";
|
|
example = ''
|
|
retains hourly 24
|
|
retain daily 365
|
|
backup /home/ localhost/
|
|
'';
|
|
type = types.lines;
|
|
description = lib.mdDoc ''
|
|
rsnapshot configuration option in addition to the defaults from
|
|
rsnapshot and this module.
|
|
|
|
Note that tabs are required to separate option arguments, and
|
|
directory names require trailing slashes.
|
|
|
|
The "extra" in the option name might be a little misleading right
|
|
now, as it is required to get a functional configuration.
|
|
'';
|
|
};
|
|
|
|
cronIntervals = mkOption {
|
|
default = {};
|
|
example = { hourly = "0 * * * *"; daily = "50 21 * * *"; };
|
|
type = types.attrsOf types.str;
|
|
description = lib.mdDoc ''
|
|
Periodicity at which intervals should be run by cron.
|
|
Note that the intervals also have to exist in configuration
|
|
as retain options.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{
|
|
services.cron.systemCronJobs =
|
|
mapAttrsToList (interval: time: "${time} root ${pkgs.rsnapshot}/bin/rsnapshot -c ${cfgfile} ${interval}") cfg.cronIntervals;
|
|
}
|
|
(mkIf cfg.enableManualRsnapshot {
|
|
environment.systemPackages = [ pkgs.rsnapshot ];
|
|
environment.etc."rsnapshot.conf".source = cfgfile;
|
|
})
|
|
]);
|
|
}
|