mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-06 21:13:40 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
83 lines
2.1 KiB
Nix
83 lines
2.1 KiB
Nix
{ lib, stdenv, fetchFromGitHub, copyPkgconfigItems, makePkgconfigItem
|
|
, version ? "2.1.0"
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "cadical";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "arminbiere";
|
|
repo = "cadical";
|
|
rev = "rel-${version}";
|
|
hash = {
|
|
"2.1.0" = "sha256-sSvJgHxsRaJ/xHEK32fox0MFI7u+pj5ERLfNn2s8kC8=";
|
|
"2.0.0" = "sha256-qoeEM9SdpuFuBPeQlCzuhPLcJ+bMQkTUTGiT8QdU8rc=";
|
|
}.${version};
|
|
};
|
|
|
|
outputs = [ "out" "dev" "lib" ];
|
|
doCheck = true;
|
|
|
|
nativeBuildInputs = [ copyPkgconfigItems ];
|
|
|
|
pkgconfigItems = [
|
|
(makePkgconfigItem {
|
|
name = "cadical";
|
|
inherit version;
|
|
cflags = [ "-I\${includedir}" ];
|
|
libs = [ "-L\${libdir}" "-lcadical" ];
|
|
variables = {
|
|
includedir = "@includedir@";
|
|
libdir = "@libdir@";
|
|
};
|
|
inherit (meta) description;
|
|
})
|
|
];
|
|
|
|
env = {
|
|
# copyPkgconfigItems will substitute these in the pkg-config file
|
|
includedir = "${placeholder "dev"}/include";
|
|
libdir = "${placeholder "lib"}/lib";
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
# fix static build
|
|
postPatch = ''
|
|
substituteInPlace makefile.in --replace-fail "ar rc" '$(AR) rc'
|
|
'';
|
|
|
|
# the configure script is not generated by autotools and does not accept the
|
|
# arguments that the default configurePhase passes like --prefix and --libdir
|
|
configurePhase = ''
|
|
runHook preConfigure
|
|
|
|
./configure
|
|
|
|
runHook postConfigure
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -Dm0755 build/cadical "$out/bin/cadical"
|
|
install -Dm0755 build/mobical "$out/bin/mobical"
|
|
install -Dm0644 src/ccadical.h "$dev/include/ccadical.h"
|
|
install -Dm0644 src/cadical.hpp "$dev/include/cadical.hpp"
|
|
install -Dm0644 build/libcadical.a "$lib/lib/libcadical.a"
|
|
mkdir -p "$out/share/doc/${pname}/"
|
|
install -Dm0755 {LICEN?E,README*,VERSION} "$out/share/doc/${pname}/"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Simplified Satisfiability Solver";
|
|
maintainers = with maintainers; [ shnarazk ];
|
|
platforms = platforms.unix;
|
|
license = licenses.mit;
|
|
homepage = "https://fmv.jku.at/cadical/";
|
|
};
|
|
}
|