mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-23 22:23:15 +00:00
075d112131
`foomatic-db-ppds` uses the Foomatic database from the packages `foomatic-db` and -- optionally -- `foomatic-db-nonfree` and the perl modules from `foomatic-db-engine` to generate about 8,800 ppd files. The general structure of the build recipe is as follows: * Merge `foomatic-db` and `foomatic-db-nonfree` into one package that represents the Foomatic database. The package `foomatic-db-nonfree` is optional as it taints the result license-wise; it will only be used if `withNonfreeDb` is to to `true` in the `callPackage` call. We create a tiny setup hook script that provides the combined database and sets an environment variable pointing to the database direcotry, which is expected by the foomatic engine. * The final package's license and version are computed from the licenses and versions of the database packages. The license is set to `free` if each database-providing package has a free license, and to `unfree` otherwise. The version is simply the highest version of the database-providing packages. * The final package uses `foomatic-compiledb` from the `foomatic-db-engine` package to extract all ppd files from the database packages. `patchPpdFilesHook` is used to patch most executable invocations in the ppd files so that they point to nix store paths. Finally, ppd files are gzipped to reduce storage (from about 550 MiB to 90 MiB installed). The "nonfree" version of the package, i.e. the version that is based on `foomatic-db-nonfree` in addition to `foomatic-db`, contains about 120 additional ppd files compared to the "free" version. Since the "free" version already produces about 8,700 ppd files and hydra won't build the "nonfree" version, the commit adds two package variables to `all-packages.nix`: * `foomatic-db-ppds` is based on `foomatic-db` only * `foomatic-db-ppds-withNonfreeDb` is also based on `foomaitc-db-nonfree` The package introduced by this commit is the result of combining other packages; it is not the build product of a simple source tarball. While it would also be possible to perform the ppd file generation directly in the build process of the database packages, this would yield further complexity as the `foomatic-db-nonfree` package needs to be combined with the `foomatic-db` package before ppd file extraction is possible. There is no upstream product with a name that could/should be used for the `name` attribute, the variable name, or for the filename in nixpkgs. Similar packages have different names across distributions: * https://repology.org/projects/?search=openprinting * https://repology.org/projects/?search=foomatic The name `foomatic-db-ppds` seems to be most common (albeit not really *that* common): * https://repology.org/project/foomatic-db-ppds/versions At least openSUSE splits their corresponding package into multiple "binary" packages (similar to our multi-output packages): * https://build.opensuse.org/package/binaries/Printing/OpenPrintingPPDs/openSUSE_Tumbleweed I considered something similar. However, after doing some statistics, I concluded that it's not worth the effort: The biggest dependencies (`perl` and `cups-filters`) are already present on most NixOS systems, and they cannot be "split away" easily since it cannot be done along a canonical line (e.g. printer driver). Splitting directly by dependency risks that ppd files unexpectedly "move from output to output" on package updates; disappearing ppd files can be quite annoying for package users.
103 lines
3.3 KiB
Nix
103 lines
3.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cups
|
|
, cups-filters
|
|
, ghostscript
|
|
, gnused
|
|
, perl
|
|
, autoconf
|
|
, automake
|
|
, patchPpdFilesHook
|
|
}:
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "foomatic-db";
|
|
version = "unstable-2022-10-03";
|
|
|
|
src = fetchFromGitHub {
|
|
# there is also a daily snapshot at the `downloadPage`,
|
|
# but it gets deleted quickly and would provoke 404 errors
|
|
owner = "OpenPrinting";
|
|
repo = "foomatic-db";
|
|
rev = "2a3c4d1bf7eadc42f936ce8989c1dd2973ea9669";
|
|
hash = "sha256-in0/j1nAQvM0NowBIBx3jj5WVMPIfZAeAk1SkuA3tjA=";
|
|
};
|
|
|
|
buildInputs = [ cups cups-filters ghostscript gnused perl ];
|
|
|
|
nativeBuildInputs = [ autoconf automake patchPpdFilesHook perl ];
|
|
|
|
# sed-substitute indirection is more robust
|
|
# against characters in paths that might need escaping
|
|
postPatch = ''
|
|
sed -Ei -e 's|^(S?BINSEARCHPATH=).+$|\1"@PATH@"|g' \
|
|
-e 's|^(DATASEARCHPATH=).+$|\1"@DATA@"|g' configure.ac
|
|
substituteInPlace configure.ac \
|
|
--subst-var PATH \
|
|
--subst-var-by DATA "${placeholder "out"}/share"
|
|
'';
|
|
|
|
preConfigure = ''
|
|
mkdir -p "${placeholder "out"}/share/foomatic/db/source"
|
|
./make_configure
|
|
'';
|
|
|
|
# don't let the intaller gzip ppd files as we would
|
|
# have to unzip them later in order to patch them
|
|
configureFlags = [ "--disable-gzip-ppds" ];
|
|
|
|
# make ppd files available to cups,
|
|
# use a package-specific subdirectory to avoid
|
|
# conflicts with other ppd-containing packages
|
|
postInstall = ''
|
|
if ! [[ -d "${placeholder "out"}/share/foomatic/db/source/PPD" ]]; then
|
|
echo "failed to create share/foomatic/db/source/PPD"
|
|
exit 1
|
|
fi
|
|
mkdir -p "${placeholder "out"}/share/cups/model"
|
|
ln -s "${placeholder "out"}/share/foomatic/db/source/PPD" \
|
|
"${placeholder "out"}/share/cups/model/foomatic-db"
|
|
'';
|
|
|
|
# Comments indicate the respective
|
|
# package the command is contained in.
|
|
ppdFileCommands = [
|
|
"cat" "date" "printf" # coreutils
|
|
"rastertohp" # cups
|
|
"foomatic-rip" # cups-filters or foomatic-filters
|
|
"gs" # ghostscript
|
|
"sed" # gnused
|
|
"perl" # perl
|
|
];
|
|
|
|
# compress ppd files
|
|
postFixup = ''
|
|
echo 'compressing ppd files'
|
|
find -H "${placeholder "out"}/share/cups/model/foomatic-db" -type f -iname '*.ppd' -print0 \
|
|
| xargs -0r -n 64 -P "$NIX_BUILD_CORES" gzip -9n
|
|
'';
|
|
|
|
meta = {
|
|
description = "OpenPrinting printer support database (free content)";
|
|
downloadPage = "https://www.openprinting.org/download/foomatic/";
|
|
homepage = "https://openprinting.github.io/projects/02-foomatic/";
|
|
license = lib.licenses.free; # mostly GPL and MIT, see README in source dir
|
|
maintainers = [ lib.maintainers.yarny ];
|
|
# list printer manufacturers here so people
|
|
# searching for ppd files can find this package
|
|
longDescription = ''
|
|
The collected knowledge about printers,
|
|
drivers, and driver options in XML files,
|
|
used by `foomatic-db-engine` to generate PPD files.
|
|
PPD files generated from the XML files in this package
|
|
are contained in the package 'foomatic-db-ppds'.
|
|
Besides the XML files, this package contains
|
|
about 6,600 PPD files, for printers from
|
|
Brother, Canon, Epson, Gestetner, HP, InfoPrint,
|
|
Infotec, KONICA_MINOLTA, Kyocera, Lanier, Lexmark, NRG,
|
|
Oce, Oki, Ricoh, Samsung, Savin, Sharp, Toshiba and Utax.
|
|
'';
|
|
};
|
|
}
|