mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-01-26 06:44:06 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
97 lines
2.3 KiB
Nix
97 lines
2.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cargo
|
|
, cmake
|
|
, deltachat-desktop
|
|
, deltachat-repl
|
|
, deltachat-rpc-server
|
|
, openssl
|
|
, perl
|
|
, pkg-config
|
|
, python3
|
|
, rustPlatform
|
|
, sqlcipher
|
|
, sqlite
|
|
, fixDarwinDylibNames
|
|
, darwin
|
|
, libiconv
|
|
}:
|
|
|
|
let
|
|
cargoLock = {
|
|
lockFile = ./Cargo.lock;
|
|
outputHashes = {
|
|
"email-0.0.20" = "sha256-rV4Uzqt2Qdrfi5Ti1r+Si1c2iW1kKyWLwOgLkQ5JGGw=";
|
|
"encoded-words-0.2.0" = "sha256-KK9st0hLFh4dsrnLd6D8lC6pRFFs8W+WpZSGMGJcosk=";
|
|
"lettre-0.9.2" = "sha256-+hU1cFacyyeC9UGVBpS14BWlJjHy90i/3ynMkKAzclk=";
|
|
};
|
|
};
|
|
in stdenv.mkDerivation rec {
|
|
pname = "libdeltachat";
|
|
version = "1.142.12";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "deltachat";
|
|
repo = "deltachat-core-rust";
|
|
rev = "v${version}";
|
|
hash = "sha256-WjzmRRHdi31Eg3UAy4rD2xrx1LVew9Y4bb50Zyv+8JA=";
|
|
};
|
|
|
|
patches = [
|
|
./no-static-lib.patch
|
|
];
|
|
|
|
cargoDeps = rustPlatform.importCargoLock cargoLock;
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
perl
|
|
pkg-config
|
|
rustPlatform.cargoSetupHook
|
|
cargo
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
fixDarwinDylibNames
|
|
];
|
|
|
|
buildInputs = [
|
|
openssl
|
|
sqlcipher
|
|
sqlite
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
darwin.apple_sdk.frameworks.CoreFoundation
|
|
darwin.apple_sdk.frameworks.Security
|
|
darwin.apple_sdk.frameworks.SystemConfiguration
|
|
libiconv
|
|
];
|
|
|
|
nativeCheckInputs = with rustPlatform; [
|
|
cargoCheckHook
|
|
];
|
|
|
|
# Sometimes -fmacro-prefix-map= can redirect __FILE__ to non-existent
|
|
# paths. This breaks packages like `python3.pkgs.deltachat`. We embed
|
|
# absolute path to headers by expanding `__FILE__`.
|
|
postInstall = ''
|
|
substituteInPlace $out/include/deltachat.h \
|
|
--replace __FILE__ '"${placeholder "out"}/include/deltachat.h"'
|
|
'';
|
|
|
|
passthru = {
|
|
inherit cargoLock;
|
|
tests = {
|
|
inherit deltachat-desktop deltachat-repl deltachat-rpc-server;
|
|
python = python3.pkgs.deltachat;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Delta Chat Rust Core library";
|
|
homepage = "https://github.com/deltachat/deltachat-core-rust/";
|
|
changelog = "https://github.com/deltachat/deltachat-core-rust/blob/${src.rev}/CHANGELOG.md";
|
|
license = licenses.mpl20;
|
|
maintainers = with maintainers; [ dotlambda ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|