mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 06:53:01 +00:00
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
136 lines
3.0 KiB
Nix
136 lines
3.0 KiB
Nix
{
|
|
fetchurl,
|
|
stdenv,
|
|
lib,
|
|
buildFHSEnv,
|
|
appimageTools,
|
|
writeShellScript,
|
|
anki,
|
|
undmg,
|
|
zstd,
|
|
cacert,
|
|
commandLineArgs ? [ ],
|
|
}:
|
|
|
|
let
|
|
pname = "anki-bin";
|
|
# Update hashes for both Linux and Darwin!
|
|
version = "24.06.3";
|
|
|
|
sources = {
|
|
linux = fetchurl {
|
|
url = "https://github.com/ankitects/anki/releases/download/${version}/anki-${version}-linux-qt6.tar.zst";
|
|
hash = "sha256-/oyQy4QHU9DCqYplcuINy5y0d2/n+fJCpgwNDURguYU=";
|
|
};
|
|
|
|
# For some reason anki distributes completely separate dmg-files for the aarch64 version and the x86_64 version
|
|
darwin-x86_64 = fetchurl {
|
|
url = "https://github.com/ankitects/anki/releases/download/${version}/anki-${version}-mac-intel-qt6.dmg";
|
|
hash = "sha256-UQRdp/GhiRGfsBF+mV6hCKpEQGFv/I9D9KTtc1p776o=";
|
|
};
|
|
darwin-aarch64 = fetchurl {
|
|
url = "https://github.com/ankitects/anki/releases/download/${version}/anki-${version}-mac-apple-qt6.dmg";
|
|
hash = "sha256-zi9yjJirNxFFD7wGa4++J+mDaE5dYZW+X0UUddGkjTU=";
|
|
};
|
|
};
|
|
|
|
unpacked = stdenv.mkDerivation {
|
|
inherit pname version;
|
|
|
|
nativeBuildInputs = [ zstd ];
|
|
src = sources.linux;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
xdg-mime () {
|
|
echo Stubbed!
|
|
}
|
|
export -f xdg-mime
|
|
|
|
PREFIX=$out bash install.sh
|
|
|
|
runHook postInstall
|
|
'';
|
|
};
|
|
|
|
meta = with lib; {
|
|
inherit (anki.meta)
|
|
license
|
|
homepage
|
|
description
|
|
mainProgram
|
|
longDescription
|
|
;
|
|
platforms = [
|
|
"x86_64-linux"
|
|
"x86_64-darwin"
|
|
"aarch64-darwin"
|
|
];
|
|
maintainers = with maintainers; [ mahmoudk1000 ];
|
|
};
|
|
|
|
passthru = {
|
|
inherit sources;
|
|
};
|
|
|
|
fhsEnvAnki = buildFHSEnv (
|
|
appimageTools.defaultFhsEnvArgs
|
|
// {
|
|
inherit pname version;
|
|
|
|
profile = ''
|
|
# anki vendors QT and mixing QT versions usually causes crashes
|
|
unset QT_PLUGIN_PATH
|
|
# anki uses the system ssl cert, without it plugins do not download/update
|
|
export SSL_CERT_FILE="${cacert}/etc/ssl/certs/ca-bundle.crt"
|
|
'';
|
|
|
|
# Dependencies of anki
|
|
targetPkgs =
|
|
pkgs:
|
|
(with pkgs; [
|
|
xorg.libxkbfile
|
|
xcb-util-cursor-HEAD
|
|
krb5
|
|
zstd
|
|
]);
|
|
|
|
runScript = writeShellScript "anki-wrapper.sh" ''
|
|
exec ${unpacked}/bin/anki ${lib.strings.escapeShellArgs commandLineArgs} "$@"
|
|
'';
|
|
|
|
extraInstallCommands = ''
|
|
ln -s ${pname} $out/bin/anki
|
|
|
|
mkdir -p $out/share
|
|
cp -R ${unpacked}/share/applications \
|
|
${unpacked}/share/man \
|
|
${unpacked}/share/pixmaps \
|
|
$out/share/
|
|
'';
|
|
|
|
inherit meta passthru;
|
|
}
|
|
);
|
|
in
|
|
|
|
if stdenv.hostPlatform.isLinux then
|
|
fhsEnvAnki
|
|
else
|
|
stdenv.mkDerivation {
|
|
inherit pname version passthru;
|
|
|
|
src = if stdenv.hostPlatform.isAarch64 then sources.darwin-aarch64 else sources.darwin-x86_64;
|
|
|
|
nativeBuildInputs = [ undmg ];
|
|
sourceRoot = ".";
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/Applications/
|
|
cp -a Anki.app $out/Applications/
|
|
'';
|
|
|
|
inherit meta;
|
|
}
|