mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-26 15:44:20 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
135 lines
2.9 KiB
Nix
135 lines
2.9 KiB
Nix
{ lib }:
|
|
|
|
rec {
|
|
|
|
/**
|
|
Throw if pred is false, else return pred.
|
|
Intended to be used to augment asserts with helpful error messages.
|
|
|
|
# Inputs
|
|
|
|
`pred`
|
|
|
|
: Predicate that needs to succeed, otherwise `msg` is thrown
|
|
|
|
`msg`
|
|
|
|
: Message to throw in case `pred` fails
|
|
|
|
# Type
|
|
|
|
```
|
|
assertMsg :: Bool -> String -> Bool
|
|
```
|
|
|
|
# Examples
|
|
:::{.example}
|
|
## `lib.asserts.assertMsg` usage example
|
|
|
|
```nix
|
|
assertMsg false "nope"
|
|
stderr> error: nope
|
|
assert assertMsg ("foo" == "bar") "foo is not bar, silly"; ""
|
|
stderr> error: foo is not bar, silly
|
|
```
|
|
|
|
:::
|
|
*/
|
|
# TODO(Profpatsch): add tests that check stderr
|
|
assertMsg = pred: msg: pred || builtins.throw msg;
|
|
|
|
/**
|
|
Specialized `assertMsg` for checking if `val` is one of the elements
|
|
of the list `xs`. Useful for checking enums.
|
|
|
|
# Inputs
|
|
|
|
`name`
|
|
|
|
: The name of the variable the user entered `val` into, for inclusion in the error message
|
|
|
|
`val`
|
|
|
|
: The value of what the user provided, to be compared against the values in `xs`
|
|
|
|
`xs`
|
|
|
|
: The list of valid values
|
|
|
|
# Type
|
|
|
|
```
|
|
assertOneOf :: String -> ComparableVal -> List ComparableVal -> Bool
|
|
```
|
|
|
|
# Examples
|
|
:::{.example}
|
|
## `lib.asserts.assertOneOf` usage example
|
|
|
|
```nix
|
|
let sslLibrary = "libressl";
|
|
in assertOneOf "sslLibrary" sslLibrary [ "openssl" "bearssl" ]
|
|
stderr> error: sslLibrary must be one of [
|
|
stderr> "openssl"
|
|
stderr> "bearssl"
|
|
stderr> ], but is: "libressl"
|
|
```
|
|
|
|
:::
|
|
*/
|
|
assertOneOf =
|
|
name: val: xs:
|
|
assertMsg (lib.elem val xs) "${name} must be one of ${lib.generators.toPretty { } xs}, but is: ${
|
|
lib.generators.toPretty { } val
|
|
}";
|
|
|
|
/**
|
|
Specialized `assertMsg` for checking if every one of `vals` is one of the elements
|
|
of the list `xs`. Useful for checking lists of supported attributes.
|
|
|
|
# Inputs
|
|
|
|
`name`
|
|
|
|
: The name of the variable the user entered `val` into, for inclusion in the error message
|
|
|
|
`vals`
|
|
|
|
: The list of values of what the user provided, to be compared against the values in `xs`
|
|
|
|
`xs`
|
|
|
|
: The list of valid values
|
|
|
|
# Type
|
|
|
|
```
|
|
assertEachOneOf :: String -> List ComparableVal -> List ComparableVal -> Bool
|
|
```
|
|
|
|
# Examples
|
|
:::{.example}
|
|
## `lib.asserts.assertEachOneOf` usage example
|
|
|
|
```nix
|
|
let sslLibraries = [ "libressl" "bearssl" ];
|
|
in assertEachOneOf "sslLibraries" sslLibraries [ "openssl" "bearssl" ]
|
|
stderr> error: each element in sslLibraries must be one of [
|
|
stderr> "openssl"
|
|
stderr> "bearssl"
|
|
stderr> ], but is: [
|
|
stderr> "libressl"
|
|
stderr> "bearssl"
|
|
stderr> ]
|
|
```
|
|
|
|
:::
|
|
*/
|
|
assertEachOneOf =
|
|
name: vals: xs:
|
|
assertMsg (lib.all (val: lib.elem val xs) vals)
|
|
"each element in ${name} must be one of ${lib.generators.toPretty { } xs}, but is: ${
|
|
lib.generators.toPretty { } vals
|
|
}";
|
|
}
|