mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-28 00:24:18 +00:00
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
73 lines
1.4 KiB
Nix
73 lines
1.4 KiB
Nix
# Version string functions.
|
|
{ lib }:
|
|
|
|
rec {
|
|
|
|
/*
|
|
Break a version string into its component parts.
|
|
|
|
Example:
|
|
splitVersion "1.2.3"
|
|
=> ["1" "2" "3"]
|
|
*/
|
|
splitVersion = builtins.splitVersion;
|
|
|
|
/*
|
|
Get the major version string from a string.
|
|
|
|
Example:
|
|
major "1.2.3"
|
|
=> "1"
|
|
*/
|
|
major = v: builtins.elemAt (splitVersion v) 0;
|
|
|
|
/*
|
|
Get the minor version string from a string.
|
|
|
|
Example:
|
|
minor "1.2.3"
|
|
=> "2"
|
|
*/
|
|
minor = v: builtins.elemAt (splitVersion v) 1;
|
|
|
|
/*
|
|
Get the patch version string from a string.
|
|
|
|
Example:
|
|
patch "1.2.3"
|
|
=> "3"
|
|
*/
|
|
patch = v: builtins.elemAt (splitVersion v) 2;
|
|
|
|
/*
|
|
Get string of the first two parts (major and minor)
|
|
of a version string.
|
|
|
|
Example:
|
|
majorMinor "1.2.3"
|
|
=> "1.2"
|
|
*/
|
|
majorMinor = v: builtins.concatStringsSep "." (lib.take 2 (splitVersion v));
|
|
|
|
/*
|
|
Pad a version string with zeros to match the given number of components.
|
|
|
|
Example:
|
|
pad 3 "1.2"
|
|
=> "1.2.0"
|
|
pad 3 "1.3-rc1"
|
|
=> "1.3.0-rc1"
|
|
pad 3 "1.2.3.4"
|
|
=> "1.2.3"
|
|
*/
|
|
pad =
|
|
n: version:
|
|
let
|
|
numericVersion = lib.head (lib.splitString "-" version);
|
|
versionSuffix = lib.removePrefix numericVersion version;
|
|
in
|
|
lib.concatStringsSep "." (lib.take n (lib.splitVersion numericVersion ++ lib.genList (_: "0") n))
|
|
+ versionSuffix;
|
|
|
|
}
|