mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-29 00:53:57 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
63 lines
1.4 KiB
Nix
63 lines
1.4 KiB
Nix
{ lib
|
|
, stdenvNoCC
|
|
, fetchzip
|
|
, runtimeShell
|
|
, bashInteractive
|
|
, glibcLocales
|
|
}:
|
|
|
|
stdenvNoCC.mkDerivation rec {
|
|
pname = "blesh";
|
|
version = "0.4.0-devel3";
|
|
|
|
src = fetchzip {
|
|
url = "https://github.com/akinomyoga/ble.sh/releases/download/v${version}/ble-${version}.tar.xz";
|
|
sha256 = "sha256-kGLp8RaInYSrJEi3h5kWEOMAbZV/gEPFUjOLgBuMhCI=";
|
|
};
|
|
|
|
dontBuild = true;
|
|
|
|
doCheck = true;
|
|
nativeCheckInputs = [ bashInteractive glibcLocales ];
|
|
preCheck = "export LC_ALL=en_US.UTF-8";
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p "$out/share/blesh/lib"
|
|
|
|
cat <<EOF >"$out/share/blesh/lib/_package.sh"
|
|
_ble_base_package_type=nix
|
|
|
|
function ble/base/package:nix/update {
|
|
echo "Ble.sh is installed by Nix. You can update it there." >&2
|
|
return 1
|
|
}
|
|
EOF
|
|
|
|
cp -rv $src/* $out/share/blesh
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
postInstall = ''
|
|
mkdir -p "$out/bin"
|
|
cat <<EOF >"$out/bin/blesh-share"
|
|
#!${runtimeShell}
|
|
# Run this script to find the ble.sh shared folder
|
|
# where all the shell scripts are living.
|
|
echo "$out/share/blesh"
|
|
EOF
|
|
chmod +x "$out/bin/blesh-share"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/akinomyoga/ble.sh";
|
|
description = "Bash Line Editor -- a full-featured line editor written in pure Bash";
|
|
mainProgram = "blesh-share";
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ aiotter ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|