mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-25 00:12:56 +00:00
5f134ec6cf
For a long time, we've had `crossLibcStdenv`, `*Cross` libc attributes,
and `*bsdCross` pre-libc package sets. This was always bad because
having "cross" things is "not declarative": the naming doesn't reflect
what packages *need* but rather how we *provide* something. This is
ugly, and creates needless friction between cross and native building.
Now, almost all of these `*Cross` attributes are gone: just these are
kept:
- Glibc's and Musl's are kept, because those packages are widely used
and I didn't want to risk changing the native builds of those at this
time.
- generic `libcCross`, `theadsCross`, and friends, because these relate
to the convolulted GCC bootstrap which still needs to be redone.
The BSD and obscure Linux or freestnanding libcs have conversely all
been made to use a new `stdenvNoLibc`, which is like the old
`crossLibcStdenv` except:
1. It usable for native and cross alike
2. It named according to what it *is* ("a standard environment without
libc but with a C compiler"), rather than some non-compositional
jargon ("the stdenv used for building libc when cross compiling",
yuck).
I should have done this change long ago, but I was stymied because of
"infinite recursions". The problem was that in too many cases we are
overriding `stdenv` to *remove* things we don't need, and this risks
cyles since those more minimal stdenvs are used to build things in the
more maximal stdenvs.
The solution is to pass `stage.nix` `stdenvNoCC`, so we can override to
*build up* rather than *tear down*. For now, the full `stdenv` is also
passed, so I don't need to change the native bootstraps, but I can see
this changing as we make things more uniform and clean those up.
(adapted from commit 51f1ecaa59)
(adapted from commit 1743662e55)
91 lines
2.4 KiB
Nix
91 lines
2.4 KiB
Nix
{
|
|
lib,
|
|
stdenvNoLibc,
|
|
makeScopeWithSplicing',
|
|
generateSplicesForMkScope,
|
|
buildPackages,
|
|
}:
|
|
|
|
let
|
|
otherSplices = generateSplicesForMkScope "openbsd";
|
|
buildOpenbsd = otherSplices.selfBuildHost;
|
|
in
|
|
|
|
makeScopeWithSplicing' {
|
|
inherit otherSplices;
|
|
f = (
|
|
self:
|
|
lib.packagesFromDirectoryRecursive {
|
|
callPackage = self.callPackage;
|
|
directory = ./pkgs;
|
|
}
|
|
// {
|
|
version = "7.5";
|
|
|
|
stdenvLibcMinimal = stdenvNoLibc.override (old: {
|
|
cc = old.cc.override {
|
|
libc = self.libcMinimal;
|
|
noLibc = false;
|
|
bintools = old.cc.bintools.override {
|
|
libc = self.libcMinimal;
|
|
noLibc = false;
|
|
sharedLibraryLoader = null;
|
|
};
|
|
};
|
|
});
|
|
|
|
makeMinimal = buildPackages.netbsd.makeMinimal.override { inherit (self) make-rules; };
|
|
|
|
# The manual callPackages below should in principle be unnecessary, but are
|
|
# necessary. See note in ../netbsd/default.nix
|
|
|
|
include = self.callPackage ./pkgs/include/package.nix {
|
|
inherit (buildOpenbsd) makeMinimal;
|
|
inherit (buildPackages.netbsd) install rpcgen mtree;
|
|
};
|
|
|
|
csu = self.callPackage ./pkgs/csu.nix {
|
|
inherit (self) include;
|
|
inherit (buildOpenbsd) makeMinimal;
|
|
inherit (buildPackages.netbsd) install;
|
|
};
|
|
|
|
libcMinimal = self.callPackage ./pkgs/libcMinimal/package.nix {
|
|
inherit (self) csu include;
|
|
inherit (buildOpenbsd) makeMinimal;
|
|
inherit (buildPackages.netbsd)
|
|
install
|
|
gencat
|
|
tsort
|
|
rpcgen
|
|
;
|
|
};
|
|
|
|
librpcsvc = self.callPackage ./pkgs/librpcsvc.nix {
|
|
inherit (buildOpenbsd) openbsdSetupHook makeMinimal lorder;
|
|
inherit (buildPackages.netbsd)
|
|
install
|
|
tsort
|
|
statHook
|
|
rpcgen
|
|
;
|
|
};
|
|
|
|
libutil = self.callPackage ./pkgs/libutil.nix {
|
|
inherit (self) libcMinimal;
|
|
inherit (buildOpenbsd) openbsdSetupHook makeMinimal lorder;
|
|
inherit (buildPackages.netbsd) install tsort statHook;
|
|
};
|
|
|
|
lorder = self.callPackage ./pkgs/lorder.nix { inherit (buildPackages.netbsd) install; };
|
|
|
|
make-rules = self.callPackage ./pkgs/make-rules/package.nix { };
|
|
|
|
mkDerivation = self.callPackage ./pkgs/mkDerivation.nix {
|
|
inherit (buildPackages.netbsd) install tsort;
|
|
inherit (buildPackages.buildPackages) rsync;
|
|
};
|
|
}
|
|
);
|
|
}
|