mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 23:13:19 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
69 lines
2.2 KiB
Nix
69 lines
2.2 KiB
Nix
{ lib, stdenv, fetchurl, bash, flex, bison, valgrind }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "lockdep";
|
|
|
|
# it would be nice to be able to pick a kernel version in sync with something
|
|
# else we already ship, but it seems userspace lockdep isn't very well maintained
|
|
# and appears broken in many kernel releases
|
|
version = "5.0.21";
|
|
fullver = "5.0.21";
|
|
src = fetchurl {
|
|
url = "mirror://kernel/linux/kernel/v5.x/linux-${version}.tar.xz";
|
|
sha256 = "1my2m9hvnvdrvzcg0fgqgaga59y2cd5zlpv7xrfj2nn98sjhglwq";
|
|
};
|
|
|
|
# ensure *this* kernel's userspace-headers are picked up before we
|
|
# fall back to those in glibc, as they will be from a mismatched
|
|
# kernel version
|
|
postPatch = ''
|
|
substituteInPlace tools/lib/lockdep/Makefile \
|
|
--replace 'CONFIG_INCLUDES =' $'CONFIG_INCLUDES = -I../../../usr/include\n#'
|
|
'';
|
|
|
|
nativeBuildInputs = [ flex bison ];
|
|
|
|
# Workaround build failure on -fno-common toolchains like upstream
|
|
# gcc-10. Otherwise build fails as:
|
|
# ld: lockdep.o:/build/linux-5.0.21/tools/lib/lockdep/../../include/linux/rcu.h:5: multiple definition of
|
|
# `rcu_scheduler_active'; common.o:/build/linux-5.0.21/tools/lib/lockdep/../../include/linux/rcu.h:5: first defined here
|
|
env.NIX_CFLAGS_COMPILE = "-fcommon";
|
|
|
|
buildPhase = ''
|
|
make defconfig
|
|
make headers_install
|
|
cd tools/lib/lockdep
|
|
make
|
|
'';
|
|
|
|
doCheck = true;
|
|
nativeCheckInputs = [ valgrind ];
|
|
checkPhase = ''
|
|
# there are more /bin/bash references than just shebangs
|
|
for f in lockdep run_tests.sh tests/*.sh; do
|
|
substituteInPlace $f \
|
|
--replace '/bin/bash' '${bash}/bin/bash'
|
|
done
|
|
|
|
./run_tests.sh
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/bin $out/lib $out/include
|
|
|
|
cp -R include/liblockdep $out/include
|
|
make install DESTDIR=$out prefix=""
|
|
|
|
substituteInPlace $out/bin/lockdep --replace "./liblockdep.so" "$out/lib/liblockdep.so.$fullver"
|
|
'';
|
|
|
|
meta = {
|
|
description = "Userspace locking validation tool built on the Linux kernel";
|
|
mainProgram = "lockdep";
|
|
homepage = "https://kernel.org/";
|
|
license = lib.licenses.gpl2Only;
|
|
platforms = lib.platforms.linux;
|
|
maintainers = [ lib.maintainers.thoughtpolice ];
|
|
};
|
|
}
|