mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 23:13:19 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
49 lines
1.3 KiB
Nix
49 lines
1.3 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, installShellFiles, testers, dnscontrol }:
|
|
|
|
buildGoModule rec {
|
|
pname = "dnscontrol";
|
|
version = "4.14.3";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "StackExchange";
|
|
repo = "dnscontrol";
|
|
rev = "v${version}";
|
|
hash = "sha256-FDxNJ6pOigasulxtAAnvHfWHQ3Ji459IQScA4dld9KQ=";
|
|
};
|
|
|
|
vendorHash = "sha256-aqS5esDroGg83NJygX8tW8P0U4YCkll98KmAfya6lKM=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
subPackages = [ "." ];
|
|
|
|
ldflags = [ "-s" "-w" "-X=main.version=${version}" ];
|
|
|
|
postInstall = ''
|
|
installShellCompletion --cmd dnscontrol \
|
|
--bash <($out/bin/dnscontrol shell-completion bash) \
|
|
--zsh <($out/bin/dnscontrol shell-completion zsh)
|
|
'';
|
|
|
|
preCheck = ''
|
|
# requires network
|
|
rm pkg/spflib/flatten_test.go pkg/spflib/parse_test.go
|
|
'';
|
|
|
|
passthru.tests = {
|
|
version = testers.testVersion {
|
|
command = "${lib.getExe dnscontrol} version";
|
|
package = dnscontrol;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Synchronize your DNS to multiple providers from a simple DSL";
|
|
homepage = "https://dnscontrol.org/";
|
|
changelog = "https://github.com/StackExchange/dnscontrol/releases/tag/${src.rev}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ SuperSandro2000 ];
|
|
mainProgram = "dnscontrol";
|
|
};
|
|
}
|