mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-22 23:13:19 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
55 lines
1.5 KiB
Nix
55 lines
1.5 KiB
Nix
{ lib, stdenv, fetchFromGitHub, makeWrapper, viu }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "uwufetch";
|
|
version = "2.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "TheDarkBug";
|
|
repo = pname;
|
|
rev = version;
|
|
hash = "sha256-cA8sajh+puswyKikr0Jp9ei+EpVkH+vhEp+pTerkUqA=";
|
|
};
|
|
|
|
postPatch = ''
|
|
substituteInPlace uwufetch.c \
|
|
--replace "/usr/lib/uwufetch" "$out/lib/uwufetch" \
|
|
--replace "/usr/local/lib/uwufetch" "$out/lib/uwufetch" \
|
|
--replace "/etc/uwufetch/config" "$out/etc/uwufetch/config"
|
|
# fix command_path for package manager (nix-store)
|
|
substituteInPlace fetch.c \
|
|
--replace "/usr/bin" "/run/current-system/sw/bin"
|
|
'' + lib.optionalString stdenv.hostPlatform.isDarwin ''
|
|
substituteInPlace Makefile \
|
|
--replace "local/bin" "bin" \
|
|
--replace "local/lib" "lib" \
|
|
--replace "local/include" "include" \
|
|
--replace "local/share" "share"
|
|
'';
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
makeFlags = [
|
|
"UWUFETCH_VERSION=${version}"
|
|
];
|
|
|
|
installFlags = [
|
|
"DESTDIR=${placeholder "out"}"
|
|
"ETC_DIR=${placeholder "out"}/etc"
|
|
];
|
|
|
|
postFixup = ''
|
|
wrapProgram $out/bin/uwufetch \
|
|
--prefix PATH ":" ${lib.makeBinPath [ viu ]}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Meme system info tool for Linux";
|
|
homepage = "https://github.com/TheDarkBug/uwufetch";
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ bbjubjub ];
|
|
mainProgram = "uwufetch";
|
|
};
|
|
}
|