From 7832afede7b910729d45ef5de522a6adfee51db3 Mon Sep 17 00:00:00 2001
From: Adam Griffiths <adam.lw.griffiths@gmail.com>
Date: Wed, 16 Sep 2020 11:13:47 +1000
Subject: [PATCH 1/2] maintainers: Add adamlwgriffiths

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 20596519e011..4464db28db43 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -182,6 +182,12 @@
     githubId = 124545;
     name = "Anthony Cowley";
   };
+  adamlwgriffiths = {
+    email = "adam.lw.griffiths@gmail.com";
+    github = "adamlwgriffiths";
+    githubId = 1239156;
+    name = "Adam Griffiths";
+  };
   adamt = {
     email = "mail@adamtulinius.dk";
     github = "adamtulinius";

From ce3b4a623f11cf49ac4f9ca633d3ab26d19a1bf1 Mon Sep 17 00:00:00 2001
From: Adam Griffiths <adam.lw.griffiths@gmail.com>
Date: Wed, 16 Sep 2020 12:22:40 +1000
Subject: [PATCH 2/2] raylib: init at 3.5.0

---
 pkgs/development/libraries/raylib/default.nix | 54 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/development/libraries/raylib/default.nix

diff --git a/pkgs/development/libraries/raylib/default.nix b/pkgs/development/libraries/raylib/default.nix
new file mode 100644
index 000000000000..47d8fdb040b2
--- /dev/null
+++ b/pkgs/development/libraries/raylib/default.nix
@@ -0,0 +1,54 @@
+{ stdenv, lib, fetchFromGitHub, fetchpatch, cmake,
+  mesa, libGLU, glfw,
+  libX11, libXi, libXcursor, libXrandr, libXinerama,
+  alsaSupport ? stdenv.hostPlatform.isLinux, alsaLib,
+  pulseSupport ? stdenv.hostPlatform.isLinux, libpulseaudio,
+  includeEverything ? true
+}:
+
+stdenv.mkDerivation rec {
+  pname = "raylib";
+  version = "3.5.0";
+
+  src = fetchFromGitHub {
+    owner = "raysan5";
+    repo = pname;
+    rev = version;
+    sha256 = "0syvd5js1lbx3g4cddwwncqg95l6hb3fdz5nsh5pqy7fr6v84kwj";
+  };
+
+  patches = [
+    # fixes examples not compiling in 3.5.0
+    (fetchpatch {
+      url = "https://patch-diff.githubusercontent.com/raw/raysan5/raylib/pull/1470.patch";
+      sha256 = "1ff5l839wl8dxwrs2bwky7kqa8kk9qmsflg31sk5vbil68dzbzg0";
+    })
+  ];
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [
+    mesa libGLU glfw libX11 libXi libXcursor libXrandr libXinerama
+  ] ++ lib.optional alsaSupport alsaLib
+    ++ lib.optional pulseSupport libpulseaudio;
+
+  # https://github.com/raysan5/raylib/wiki/CMake-Build-Options
+  cmakeFlags = [
+    "-DUSE_EXTERNAL_GLFW=ON"
+    "-DSHARED=ON"
+    "-DBUILD_EXAMPLES=OFF"
+  ] ++ lib.optional includeEverything "-DINCLUDE_EVERYTHING=ON";
+
+  # fix libasound.so/libpulse.so not being found
+  preFixup = ''
+    ${lib.optionalString alsaSupport "patchelf --add-needed ${alsaLib}/lib/libasound.so $out/lib/libraylib.so.${version}"}
+    ${lib.optionalString pulseSupport "patchelf --add-needed ${libpulseaudio}/lib/libpulse.so $out/lib/libraylib.so.${version}"}
+  '';
+
+  meta = with lib; {
+    description = "A simple and easy-to-use library to enjoy videogames programming";
+    homepage = "http://www.raylib.com/";
+    license = licenses.zlib;
+    maintainers = with maintainers; [ adamlwgriffiths ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 5c2ef527ca9c..c2a2139a5f11 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -16337,6 +16337,8 @@ in
 
   raul = callPackage ../development/libraries/audio/raul { };
 
+  raylib = callPackage ../development/libraries/raylib { };
+
   readline = readline6;
   readline6 = readline63;