From f840a51a49cad3cf6e7f772dfc6b4e81adc49588 Mon Sep 17 00:00:00 2001
From: hellwolf <hellwolf@freehell.org>
Date: Sun, 21 Apr 2024 00:10:37 +0300
Subject: [PATCH] insync-emblem-icons: init at 3.8.7.50516

---
 .../in/insync-emblem-icons/package.nix        | 47 +++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 pkgs/by-name/in/insync-emblem-icons/package.nix

diff --git a/pkgs/by-name/in/insync-emblem-icons/package.nix b/pkgs/by-name/in/insync-emblem-icons/package.nix
new file mode 100644
index 000000000000..b31f05170a63
--- /dev/null
+++ b/pkgs/by-name/in/insync-emblem-icons/package.nix
@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  dpkg,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "insync-emblem-icons";
+  version = "3.8.7.50516";
+
+  src = fetchurl rec {
+    urls = [
+      "https://cdn.insynchq.com/builds/linux/insync-emblem-icons_${finalAttrs.version}_all.deb"
+      "https://web.archive.org/web/20240409081214/${builtins.elemAt urls 0}"
+    ];
+    hash = "sha256-uALaIxETEEkjDTx331uIsb4VswWk2K0dGuDMYH8v5U8=";
+  };
+
+  nativeBuildInputs = [ dpkg ];
+
+  unpackPhase = ''
+    runHook preUnpack
+
+    dpkg-deb --fsys-tarfile "$src" | tar -x --no-same-permissions --no-same-owner
+
+    runHook postUnpack
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    cp -R usr/* $out/
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = licenses.unfree;
+    maintainers = with maintainers; [ hellwolf ];
+    homepage = "https://www.insynchq.com";
+    description = "This package contains the file manager emblem icons for Insync file manager extensions";
+  };
+})