From efc51bf1a1a155aa4c20e3548c3c0d12423a643e Mon Sep 17 00:00:00 2001
From: Anthony ROUSSEL <anthony@roussel.dev>
Date: Thu, 25 Jul 2024 21:31:06 +0200
Subject: [PATCH] python311Packages.python-barbicanclient: init at 7.0.0

https://wiki.openstack.org/wiki/Barbican
https://opendev.org/openstack/python-barbicanclient
---
 .../python-barbicanclient/default.nix         | 70 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  1 +
 pkgs/top-level/python-packages.nix            |  2 +
 3 files changed, 73 insertions(+)
 create mode 100644 pkgs/development/python-modules/python-barbicanclient/default.nix

diff --git a/pkgs/development/python-modules/python-barbicanclient/default.nix b/pkgs/development/python-modules/python-barbicanclient/default.nix
new file mode 100644
index 000000000000..cefe9412e86e
--- /dev/null
+++ b/pkgs/development/python-modules/python-barbicanclient/default.nix
@@ -0,0 +1,70 @@
+{
+  lib,
+  buildPythonPackage,
+  cliff,
+  fetchFromGitea,
+  keystoneauth1,
+  oslo-i18n,
+  oslo-serialization,
+  oslo-utils,
+  pbr,
+  pythonOlder,
+  requests-mock,
+  requests,
+  setuptools,
+  stestr,
+}:
+
+buildPythonPackage rec {
+  pname = "python-barbicanclient";
+  version = "7.0.0";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchFromGitea {
+    domain = "opendev.org";
+    owner = "openstack";
+    repo = "python-barbicanclient";
+    rev = version;
+    hash = "sha256-odoYyBulOQkjUpymFyZgvI+DYmdHJY3PaG8hh2ms+/0=";
+  };
+
+  env.PBR_VERSION = version;
+
+  build-system = [
+    pbr
+    setuptools
+  ];
+
+  dependencies = [
+    cliff
+    keystoneauth1
+    oslo-i18n
+    oslo-serialization
+    oslo-utils
+    requests
+  ];
+
+  doCheck = true;
+
+  nativeCheckInputs = [
+    requests-mock
+    stestr
+  ];
+
+  checkPhase = ''
+    runHook preCheck
+    stestr run
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [ "barbicanclient" ];
+
+  meta = {
+    homepage = "https://opendev.org/openstack/python-barbicanclient";
+    description = "Client library for OpenStack Barbican API";
+    license = lib.licenses.asl20;
+    maintainers = lib.teams.openstack.members;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index b2018bdc1ec2..df6f1212d1ca 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -23433,6 +23433,7 @@ with pkgs;
   openslp = callPackage ../development/libraries/openslp { };
 
   openstackclient = with python311Packages; toPythonApplication python-openstackclient;
+  barbicanclient = with python311Packages; toPythonApplication python-barbicanclient;
   glanceclient = with python311Packages; toPythonApplication python-glanceclient;
   heatclient = with python311Packages; toPythonApplication python-heatclient;
   ironicclient = with python311Packages; toPythonApplication python-ironicclient;
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index b31e805460b6..22124d056bfe 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12571,6 +12571,8 @@ self: super: with self; {
 
   python-axolotl-curve25519 = callPackage ../development/python-modules/python-axolotl-curve25519 { };
 
+  python-barbicanclient = callPackage ../development/python-modules/python-barbicanclient { };
+
   python-barcode = callPackage ../development/python-modules/python-barcode { };
 
   python-baseconv = callPackage ../development/python-modules/python-baseconv { };