From ed18fab640e343bbee1afe81569e5e6d83fcf15a Mon Sep 17 00:00:00 2001
From: Mathieu Rene <mathieu.rene@gmail.com>
Date: Thu, 25 Jul 2024 21:46:12 -0400
Subject: [PATCH] corefreq: init at 1.98.4

---
 pkgs/os-specific/linux/corefreq/default.nix | 48 +++++++++++++++++++++
 pkgs/top-level/linux-kernels.nix            |  2 +
 2 files changed, 50 insertions(+)
 create mode 100644 pkgs/os-specific/linux/corefreq/default.nix

diff --git a/pkgs/os-specific/linux/corefreq/default.nix b/pkgs/os-specific/linux/corefreq/default.nix
new file mode 100644
index 000000000000..66102f27cbc4
--- /dev/null
+++ b/pkgs/os-specific/linux/corefreq/default.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  kernel,
+  hostPlatform,
+  # See the official readme for a list of optional flags:
+  # https://github.com/cyring/CoreFreq/blob/master/README.md
+  extraFlags ? [ ],
+}:
+
+stdenv.mkDerivation rec {
+  pname = "corefreq";
+  version = "1.98.4";
+
+  src = fetchFromGitHub {
+    owner = "cyring";
+    repo = "CoreFreq";
+    rev = version;
+    hash = "sha256-ljo8EDoJmcdfVvC8s+Xbf5TsYruvSOU1OSYBPwQst1c=";
+  };
+
+  nativeBuildInputs = kernel.moduleBuildDependencies;
+
+  env.NIX_CFLAGS_COMPILE = "-I${src}/${hostPlatform.qemuArch}";
+  makeFlags = [
+    "KERNELDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
+    "INSTALL_MOD_PATH=$(out)"
+  ] ++ extraFlags;
+
+  preInstall = ''
+    mkdir -p $out/bin
+  '';
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  meta = {
+    description = "CPU monitoring and tuning software designed for 64-bit processors";
+    homepage = "https://github.com/cyring/CoreFreq";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ mrene ];
+    mainProgram = "corefreq-cli";
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+    ];
+  };
+}
diff --git a/pkgs/top-level/linux-kernels.nix b/pkgs/top-level/linux-kernels.nix
index 4255d0c036e8..3129d7cfef88 100644
--- a/pkgs/top-level/linux-kernels.nix
+++ b/pkgs/top-level/linux-kernels.nix
@@ -531,6 +531,8 @@ in {
 
     turbostat = callPackage ../os-specific/linux/turbostat { };
 
+    corefreq = callPackage ../os-specific/linux/corefreq { };
+
     trelay = callPackage ../os-specific/linux/trelay { };
 
     universal-pidff = callPackage ../os-specific/linux/universal-pidff { };