From df3a19b9d7f408f3ed21842f96fd79ed52c39a20 Mon Sep 17 00:00:00 2001
From: Kira Bruneau <kira.bruneau@gmail.com>
Date: Tue, 26 Jan 2021 20:23:09 -0500
Subject: [PATCH] vkBasalt: init at 0.3.2.4

---
 pkgs/tools/graphics/vkBasalt/default.nix | 42 ++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix          |  4 +++
 2 files changed, 46 insertions(+)
 create mode 100644 pkgs/tools/graphics/vkBasalt/default.nix

diff --git a/pkgs/tools/graphics/vkBasalt/default.nix b/pkgs/tools/graphics/vkBasalt/default.nix
new file mode 100644
index 000000000000..50cbe0481311
--- /dev/null
+++ b/pkgs/tools/graphics/vkBasalt/default.nix
@@ -0,0 +1,42 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, glslang
+, meson
+, ninja
+, pkg-config
+, libX11
+, spirv-headers
+, vulkan-headers
+, vkBasalt32
+}:
+
+stdenv.mkDerivation rec {
+  pname = "vkBasalt";
+  version = "0.3.2.4";
+
+  src = fetchFromGitHub {
+    owner = "DadSchoorse";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "01iplj6dlw2vl35hyci5m5yp8jmzcwng6c3jk3wn97jpv6m3hjqz";
+  };
+
+  nativeBuildInputs = [ glslang meson ninja pkg-config ];
+  buildInputs = [ libX11 spirv-headers vulkan-headers ];
+  mesonFlags = [ "-Dappend_libdir_vkbasalt=true" ];
+
+  # Include 32bit layer in 64bit build
+  postInstall = lib.optionalString (stdenv.hostPlatform.system == "x86_64-linux") ''
+    ln -s ${vkBasalt32}/share/vulkan/implicit_layer.d/vkBasalt.json \
+      "$out/share/vulkan/implicit_layer.d/vkBasalt32.json"
+  '';
+
+  meta = with lib; {
+    description = "A Vulkan post processing layer for Linux";
+    homepage = "https://github.com/DadSchoorse/vkBasalt";
+    license = licenses.zlib;
+    maintainers = with maintainers; [ metadark ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 4fd88228462c..ba481b145fea 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -8602,6 +8602,10 @@ in
 
   vix = callPackage ../tools/misc/vix { };
 
+  vkBasalt = callPackage ../tools/graphics/vkBasalt {
+    vkBasalt32 = pkgsi686Linux.vkBasalt;
+  };
+
   vnc2flv = callPackage ../tools/video/vnc2flv {};
 
   vncrec = callPackage ../tools/video/vncrec { };