From a67aec1746b8780fae3ca357d47010aa10e13fa8 Mon Sep 17 00:00:00 2001
From: Peter Hoeg <peter@hoeg.com>
Date: Tue, 6 Aug 2019 12:46:14 +0800
Subject: [PATCH] maestral: init at 0.2.6

---
 .../networking/maestral/default.nix           | 38 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  4 ++
 2 files changed, 42 insertions(+)
 create mode 100644 pkgs/applications/networking/maestral/default.nix

diff --git a/pkgs/applications/networking/maestral/default.nix b/pkgs/applications/networking/maestral/default.nix
new file mode 100644
index 000000000000..bfacac2eaf4d
--- /dev/null
+++ b/pkgs/applications/networking/maestral/default.nix
@@ -0,0 +1,38 @@
+{ lib, python3Packages, fetchFromGitHub
+, withGui ? false, wrapQtAppsHook ? null }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "maestral${lib.optionalString withGui "-gui"}";
+  version = "0.2.6";
+
+  src = fetchFromGitHub {
+    owner = "SamSchott";
+    repo = "maestral-dropbox";
+    rev = "v${version}";
+    sha256 = "1nfjm58f6hnqbx9xnz2h929s2175ka1yf5jjlk4i60v0wppnrrdf";
+  };
+
+  disabled = python3Packages.pythonOlder "3.6";
+
+  propagatedBuildInputs = (with python3Packages; [
+    blinker click dropbox keyring keyrings-alt requests u-msgpack-python watchdog
+  ] ++ lib.optional withGui pyqt5);
+
+  nativeBuildInputs = lib.optional withGui wrapQtAppsHook;
+
+  postInstall = lib.optionalString withGui ''
+    makeQtWrapper $out/bin/maestral $out/bin/maestral-gui \
+      --add-flags gui
+  '';
+
+  # no tests
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Open-source Dropbox client for macOS and Linux";
+    license = licenses.mit;
+    maintainers = with maintainers; [ peterhoeg ];
+    platforms = platforms.unix;
+    inherit (src.meta) homepage;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 9d022733584c..5d7033de5b7f 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -20391,6 +20391,10 @@ in
 
   dropbox-cli = callPackage ../applications/networking/dropbox/cli.nix { };
 
+  maestral = callPackage ../applications/networking/maestral { };
+
+  maestral-gui = libsForQt5.callPackage ../applications/networking/maestral { withGui = true; };
+
   insync = callPackage ../applications/networking/insync { };
 
   libstrangle = callPackage ../tools/X11/libstrangle {